RSI-ADI-Combo

//@version=4
// Version 1.1 - jan 2020 - Bas Willemstijn
study(title="RSI-ADI-Combo [Numchuck]", shorttitle="RSI-ADX", overlay=false)

// ADI with AD+ and AD- gives first indication of direction of trend
len2 = input(14, minval=1, title="DI Length")
lensig = input(14, title="ADX Smoothing", minval=1, maxval=50)


up1 = change(high)
down1 = -change(low)
trur = rma(tr, len2)

plus = fixnan(100 * rma(up1 > down1 and up1 > 0 ? up1 : 0, len2) / trur)
minus = fixnan(100 * rma(down1 > up1 and down1 > 0 ? down1 : 0, len2) / trur)

sum = plus + minus
adx = 100 * rma(abs(plus - minus) / (sum == 0 ? 1 : sum), lensig)

osob = input(40, title="Exhaustion Level for ADX, default = 40")


col = adx <= 10 ? color.gray : adx > 10 and adx <= 20 and plus > minus ? #98FF98 : 
   adx > 10 and adx <= 20 and plus < minus ? #E77471 : 
   adx > 20 and adx <= osob and plus > minus ? color.lime : 
   adx > 20 and adx <= osob and plus < minus ? color.red : 
   adx > osob and plus > minus ? color.green : 
   adx > osob and plus < minus ? color.maroon : color.white
// barcolor(col)
// //plot(plus, color=lime, title="+DI", style=line, linewidth=3)
// //plot(minus, color=red, title="-DI", style=line, linewidth=3)
plot(adx, color=col, title="ADX", style=plot.style_columns)
plot(0, title="0 Line", style=plot.style_line, linewidth=1, color=color.gray)
plot(10, title="10 Line", style=plot.style_circles, linewidth=1, color=color.gray)
plot(20, title="20 Line", style=plot.style_circles, linewidth=1, color=color.gray)
plot(osob, title="10 Line", style=plot.style_circles, linewidth=1, color=color.gray)

// Money Flow Index
length = input(title="Length", defval=14)

rawMoneyFlow = hlc3 * volume

positiveMoneyFlow = 0.0
positiveMoneyFlow := hlc3 > hlc3[1] ? positiveMoneyFlow + rawMoneyFlow : positiveMoneyFlow
negativeMoneyFlow = 0.0
negativeMoneyFlow := hlc3 < hlc3[1] ? negativeMoneyFlow + rawMoneyFlow : negativeMoneyFlow

moneyFlowRatio = sma(positiveMoneyFlow, length) / sma(negativeMoneyFlow, length)

moneyFlowIndex = 100 - 100 / (1 + moneyFlowRatio)

plot(moneyFlowIndex, title="MFI", style=plot.style_line, linewidth=3, color=color.yellow)

// RSI gives signal voor bullish or bearish position in combination with Aroon and ADI
src = close
len = input(14, minval=1, title="RSI Length")
up = rma(max(change(src), 0), len)
down = rma(-min(change(src), 0), len)
rsi = down == 0 ? 100 : up == 0 ? 0 : 100 - 100 / (1 + up / down)

plot(rsi, title="RSI", style=plot.style_line, linewidth=3, color=color.black)
band2 = hline(80, title="Overbought signal", linestyle=hline.style_dashed, linewidth=1, color=color.red)
band1 = hline(50, title="Buy/Sell signal Line", linestyle=hline.style_dashed, linewidth=2, color=color.silver)
band0 = hline(20, title="Oversold signal", linestyle=hline.style_dashed, linewidth=1, color=color.lime)