2x MA Moving Average

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Piotr Kowalski "piecioshka"
// Docs (EN): https://github.com/piecioshka/tradingview-pine-scripts/blob/main/indicators/overlays/2x-ma/2x-ma.md
// Docs (PL): https://github.com/piecioshka/tradingview-pine-scripts/blob/main/indicators/overlays/2x-ma/2x-ma.pl.md

//@version=6
indicator('2x MA = Moving Average', overlay = true, max_labels_count=500)

aLen = input(50, 'Length', group='Short')
aType = input.string(title='Type', options=['SMA', 'EMA', 'WMA', 'VWMA', 'RMA'], group='Short', defval='SMA')
aColor = input.color(color.rgb(56, 104, 174), 'Color', group='Short')
aSeries = switch aType
    'SMA' => ta.sma(close, aLen)
    'EMA' => ta.ema(close, aLen)
    'WMA' => ta.wma(close, aLen)
    'VWMA' => ta.vwma(close, aLen)
    'RMA' => ta.rma(close, aLen)
    => na

bLen = input(200, 'Length', group='Long')
bType = input.string(title='Type', options=['SMA', 'EMA', 'WMA', 'VWMA', 'RMA'], group='Long', defval='SMA')
bColor = input.color(color.rgb(215, 107, 52), 'Color', group='Long')
bSeries = switch bType
    'SMA' => ta.sma(close, bLen)
    'EMA' => ta.ema(close, bLen)
    'WMA' => ta.wma(close, bLen)
    'VWMA' => ta.vwma(close, bLen)
    'RMA' => ta.rma(close, bLen)
    => na

showLabels = input.bool(true, 'Show labels (length and type)', group='Labels')
showTrades = input.bool(true, 'Signal markers', group='Labels', tooltip='Markers at crosses: below the candle (long) at a golden cross (the short MA crosses the long one up), above the candle (sell) at a death cross. Shape and size in the Appearance group.')

gA = 'Appearance'
shapeName = input.string('Triangle', 'Marker shape', options=['Triangle', 'Arrow', 'Label arrow', 'Circle', 'Diamond'], group=gA, tooltip='Triangle - solid triangle.\nArrow - small thin arrow.\nLabel arrow - arrow-shaped label bubble.\nCircle / Diamond - neutral dot markers.')
sizeName  = input.string('Small', 'Marker size', options=['Tiny', 'Small', 'Normal', 'Large'], group=gA)

// Markers as labels - the shape is picked from an input, which plotshape() cannot do (its style must be a constant).
upStyle    = shapeName == 'Arrow' ? label.style_arrowup : shapeName == 'Label arrow' ? label.style_label_up : shapeName == 'Circle' ? label.style_circle : shapeName == 'Diamond' ? label.style_diamond : label.style_triangleup
downStyle  = shapeName == 'Arrow' ? label.style_arrowdown : shapeName == 'Label arrow' ? label.style_label_down : shapeName == 'Circle' ? label.style_circle : shapeName == 'Diamond' ? label.style_diamond : label.style_triangledown
markerSize = sizeName == 'Tiny' ? size.tiny : sizeName == 'Normal' ? size.normal : sizeName == 'Large' ? size.large : size.small

plot(aSeries, 'Short', color=color.new(aColor, 30), linewidth=2, force_overlay=true)
plot(bSeries, 'Long', color=color.new(bColor, 30), linewidth=2, force_overlay=true, linestyle=plot.linestyle_dotted)

updateLabel(label lbl, float y, string txt, color col) =>
    label result = lbl
    if na(result)
        result := label.new(bar_index, y, txt, style=label.style_label_left, color=color.new(color.black, 100), textcolor=col, force_overlay=true)
    label.set_xy(result, bar_index, y)
    label.set_text(result, txt)
    result

var label aLabel = na
var label bLabel = na

if showLabels and barstate.islast
    aLabel := updateLabel(aLabel, aSeries, str.tostring(aLen) + ' ' + aType, aColor)
    bLabel := updateLabel(bLabel, bSeries, str.tostring(bLen) + ' ' + bType, bColor)

crossUp = ta.crossover(aSeries, bSeries)
crossDn = ta.crossunder(aSeries, bSeries)

// Signal markers (as in Accumulation / Distribution Density):
// golden cross = green marker below the candle (long), death cross = red marker above (sell)
if showTrades and crossUp
    label.new(bar_index, na, '', yloc=yloc.belowbar, style=upStyle, color=color.green, size=markerSize, force_overlay=true)
if showTrades and crossDn
    label.new(bar_index, na, '', yloc=yloc.abovebar, style=downStyle, color=color.red, size=markerSize, force_overlay=true)

// --- Alerts ---
alertcondition(crossUp, 'MA: cross up',   'The short MA crossed the long one up (golden cross, bullish impulse)')
alertcondition(crossDn, 'MA: cross down', 'The short MA crossed the long one down (death cross, bearish impulse)')