MA Spread Histogram

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Piotr Kowalski "piecioshka"
// Docs (EN): https://github.com/piecioshka/tradingview-pine-scripts/blob/main/indicators/oscillators/ma-spread-histogram/ma-spread-histogram.md
// Docs (PL): https://github.com/piecioshka/tradingview-pine-scripts/blob/main/indicators/oscillators/ma-spread-histogram/ma-spread-histogram.pl.md

//@version=6
indicator('MA Spread Histogram', overlay=false, max_labels_count=500)

aLen = input(50, 'Length', group='Short')
aType = input.string(title='Type', options=['SMA', 'EMA', 'WMA', 'VWMA', 'RMA'], group='Short', defval='SMA')
aSeries = switch aType
    'SMA' => ta.sma(close, aLen)
    'EMA' => ta.ema(close, aLen)
    'WMA' => ta.wma(close, aLen)
    'VWMA' => ta.vwma(close, aLen)
    'RMA' => ta.rma(close, aLen)
    => na

bLen = input(200, 'Length', group='Long')
bType = input.string(title='Type', options=['SMA', 'EMA', 'WMA', 'VWMA', 'RMA'], group='Long', defval='SMA')
bSeries = switch bType
    'SMA' => ta.sma(close, bLen)
    'EMA' => ta.ema(close, bLen)
    'WMA' => ta.wma(close, bLen)
    'VWMA' => ta.vwma(close, bLen)
    'RMA' => ta.rma(close, bLen)
    => na

gA = 'Appearance'
shapeName = input.string('Triangle', 'Marker shape', options=['Triangle', 'Arrow', 'Label arrow', 'Circle', 'Diamond'], group=gA, tooltip='Triangle - solid triangle.\nArrow - small thin arrow.\nLabel arrow - arrow-shaped label bubble.\nCircle / Diamond - neutral dot markers.')
sizeName  = input.string('Small', 'Marker size', options=['Tiny', 'Small', 'Normal', 'Large'], group=gA)

// Markers as labels - the shape is picked from an input, which plotshape() cannot do (its style must be a constant).
upStyle    = shapeName == 'Arrow' ? label.style_arrowup : shapeName == 'Label arrow' ? label.style_label_up : shapeName == 'Circle' ? label.style_circle : shapeName == 'Diamond' ? label.style_diamond : label.style_triangleup
downStyle  = shapeName == 'Arrow' ? label.style_arrowdown : shapeName == 'Label arrow' ? label.style_label_down : shapeName == 'Circle' ? label.style_circle : shapeName == 'Diamond' ? label.style_diamond : label.style_triangledown
markerSize = sizeName == 'Tiny' ? size.tiny : sizeName == 'Normal' ? size.normal : sizeName == 'Large' ? size.large : size.small

histogram = aSeries - bSeries
histColor = histogram >= 0 ? histogram > histogram[1] ? color.new(color.green, 50) : color.new(color.green, 80) : histogram < histogram[1] ? color.new(color.red, 50) : color.new(color.red, 80)

plot(histogram, 'Histogram', color=histColor, linewidth=2, style=plot.style_columns)
hline(0, 'Zero', color=color.gray, linestyle=hline.style_solid)

crossUp = ta.crossover(aSeries, bSeries)
crossDn = ta.crossunder(aSeries, bSeries)

// Short crosses long UP (histogram goes above zero) -> bullish impulse -> BUY OPEN.
// Marker below the candle (as in Accumulation / Distribution Density).
if (crossUp)
    line.new(bar_index, histogram, bar_index, histogram, color=color.new(color.green, 70), style=line.style_dashed, extend=extend.left)
    line.new(bar_index, high, bar_index, low, color=color.new(color.green, 70), style=line.style_dashed, extend=extend.right, force_overlay=true)
    label.new(bar_index, na, '', yloc=yloc.belowbar, style=upStyle, color=color.green, size=markerSize, force_overlay=true)

// Short crosses long DOWN (histogram goes below zero) -> bearish impulse -> BUY CLOSE.
// Marker above the candle.
if (crossDn)
    line.new(bar_index, histogram, bar_index, histogram, color=color.new(color.red, 70), style=line.style_dashed, extend=extend.left)
    line.new(bar_index, high, bar_index, low, color=color.new(color.red, 70), style=line.style_dashed, extend=extend.right, force_overlay=true)
    label.new(bar_index, na, '', yloc=yloc.abovebar, style=downStyle, color=color.red, size=markerSize, force_overlay=true)

// --- Alerts ---
alertcondition(crossUp, 'MA spread: cross up',   'The histogram crossed zero up - the short MA crossed the long one up (bullish impulse)')
alertcondition(crossDn, 'MA spread: cross down', 'The histogram crossed zero down - the short MA crossed the long one down (bearish impulse)')