Week candle backward shift

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © chaise_cogent
//
// Script version = 2.1-reduced logs
// The script slides start date of 1-WEEK candles to the specified number of days BACKWARD
// For example, "shift_days = 1" means that candles start on Sunday and the last day is Monday

//@version=6
indicator("Week candle backward shift", overlay=false, max_bars_back = 20)

var shift_days = input.int(0, title = "Days to shift backward", minval=0, maxval=6)
bull_color = input.color(color.new(color.green, 20), title = "Bullish Candle")
bear_color = input.color(color.new(color.red, 20), title = "Bearish Candle")

var int start_day_index = dayofweek + shift_days + 1
var int end_day_index = start_day_index - 6

var int last_candle_week_length = if dayofweek(timenow) == dayofweek.monday
    shift_days + 1
else if dayofweek(timenow) == dayofweek.tuesday
    shift_days + 2
else if dayofweek(timenow) == dayofweek.wednesday
    shift_days + 3
else if dayofweek(timenow) == dayofweek.thursday
    shift_days + 4
else if dayofweek(timenow) == dayofweek.friday
    shift_days + 5
else if dayofweek(timenow) == dayofweek.saturday
    shift_days + 6
else // SUNDAY
    shift_days + 7
log.info('current-day={0}, last-candle-week-len={1}',
  dayofweek(time_close(timeframe.period)), last_candle_week_length)

var int last_candle_start_index = if dayofweek(timenow) == dayofweek.monday
    shift_days + 0
else if dayofweek(timenow) == dayofweek.tuesday
    shift_days + 1
else if dayofweek(timenow) == dayofweek.wednesday
    shift_days + 2
else if dayofweek(timenow) == dayofweek.thursday
    shift_days + 3
else if dayofweek(timenow) == dayofweek.friday
    shift_days + 4
else if dayofweek(timenow) == dayofweek.saturday
    shift_days + 5
else // SUNDAY
    shift_days + 6
log.info('current-day={0}, day-bar-start-index={1}',
  dayofweek(time_close(timeframe.period)), last_candle_start_index)

dailyOpen = request.security(syminfo.tickerid, "1D", open[start_day_index])
dailyHigh = request.security(syminfo.tickerid, "1D", ta.highest(high[end_day_index], 7))
dailyLow = request.security(syminfo.tickerid, '1D', ta.lowest(low[end_day_index], 7))
dailyClose = request.security(syminfo.tickerid, "1D", close[end_day_index])

// Special case for the current (unclosed) candle which length changes from 1 to 7 days
daily_open_last_candle = request.security(syminfo.tickerid, "1D", open[last_candle_start_index]) 
daily_high_last_candle = request.security(syminfo.tickerid, "1D", ta.highest(high[0], last_candle_week_length))
daily_low_last_candle = request.security(syminfo.tickerid, '1D', ta.lowest(low[0], last_candle_week_length))
daily_close_last_candle = request.security(syminfo.tickerid, "1D", close[0])

// Assign Weekly values to the custom open/high/low/close variables
var series float custom_open = na
var series float custom_close = na
var series float custom_high = na
var series float custom_low = na
if timeframe.isweekly and timeframe.multiplier == 1
    if bar_index != last_bar_index
        custom_open := dailyOpen
        custom_high := dailyHigh
        custom_low := dailyLow
        custom_close := dailyClose
    else
        custom_open := daily_open_last_candle
        custom_high := daily_high_last_candle
        custom_low := daily_low_last_candle
        custom_close := daily_close_last_candle
else
    custom_open := open
    custom_high := high
    custom_low := low
    custom_close := close

is_green = custom_open <= custom_close
candle_color = is_green ? bull_color : bear_color

plotcandle(custom_open, custom_high, custom_low, custom_close,
  color = candle_color, wickcolor = candle_color, bordercolor = candle_color,
  title = 'OHLC', force_overlay = false)