Multi-Ticker Anchored Candles

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © SamRecio

//@version=6
indicator("Multi-Ticker Anchored Candles", shorttitle = "MTAC", overlay = true, max_lines_count = 500)

///_____________________________________________________________________________________________________________________
///Inputs
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

period = input.timeframe("D", title = "Period", inline = "anchor", group = "Anchor")
col1 = input.color(color.gray, title = "", inline = "anchor", group = "Anchor")

s1_tog = input.bool(true, title = "", inline  = "symbol1", group = "Symbols")
s1 = input.symbol("NQ1!", title = "Symbol 1", inline  = "symbol1", group = "Symbols")
s1_col = input.color(color.new(#ff033e,25), title = "", inline = "symbol1", group = "Symbols")

s2_tog = input.bool(true, title = "", inline  = "symbol2", group = "Symbols")
s2 = input.symbol("RTY1!", title = "Symbol 2", inline  = "symbol2", group = "Symbols")
s2_col = input.color(color.new(#004d92,25), title = "", inline = "symbol2", group = "Symbols")

s3_tog = input.bool(true, title = "", inline  = "symbol3", group = "Symbols")
s3 = input.symbol("YM1!", title = "Symbol 3", inline  = "symbol3", group = "Symbols")
s3_col = input.color(color.new(#3daa45,25), title = "", inline = "symbol3", group = "Symbols")

show_splits = input.bool(true, title = "Session Breaks", group = "Additional Display Options")
show_open = input.bool(true, title = "Open Price", group = "Additional Display Options")

show_t = input.bool(true, title = "Ticker", group = "Label Options")
show_price = input.bool(true, title = "Price", group = "Label Options")
show_per = input.bool(true, title = "Percent", group = "Label Options")
show_net = input.bool(false, title = "Net", group = "Label Options")

invis = color.rgb(0,0,0,100)

///_____________________________________________________________________________________________________________________
///Setup
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

newtf = timeframe.change(period)

//Chart Data
var float dayo = na
dayo := newtf?open:dayo

///_____________________________________________________________________________________________________________________
///Functions
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

add_plus(_val) => _val > 0 ? "+" : ""

get_lab(_s,_cv,_per,_val) =>
    t = show_t ? str.split(_s,":").get(1) + " " : ""
    price = show_price ? str.tostring(_cv, format.mintick) + " " : ""
    per = show_per ? add_plus(_per) + str.tostring(_per, format.percent) + " " : ""
    net = show_net ? add_plus(_val) + str.tostring(_val, format.mintick) + " " : ""
    t + price + per + net

//Symbol Candles
get_scaled_data(_symbol,_tog) =>
    [s_o,s_h,s_l,s_c] = request.security(_symbol,"",[open,high,low,close])

    var float s_dayo = na
    s_dayo := newtf ? s_o : s_dayo

    s_o_pgain = (1+(s_o - s_dayo) / s_dayo) * dayo
    s_h_pgain = (1+(s_h - s_dayo) / s_dayo) * dayo
    s_l_pgain = (1+(s_l - s_dayo) / s_dayo) * dayo
    s_c_pgain = (1+(s_c - s_dayo) / s_dayo) * dayo

    s_pgain_per = ((s_c_pgain/dayo)-1)*100
    s_value = (s_c - s_dayo) 

    [s_c,s_o_pgain,s_h_pgain,s_l_pgain,s_c_pgain,s_pgain_per,s_value]

///_____________________________________________________________________________________________________________________
///Candle Calcs
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

[s1_cv,s1_o,s1_h,s1_l,s1_c,s1_per,s1_val] = get_scaled_data(s1,s1_tog)
[s2_cv,s2_o,s2_h,s2_l,s2_c,s2_per,s2_val] = get_scaled_data(s2,s2_tog)
[s3_cv,s3_o,s3_h,s3_l,s3_c,s3_per,s3_val] = get_scaled_data(s3,s3_tog)

///_____________________________________________________________________________________________________________________
///Display
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

//Symbol 1
    //Candles
plotcandle(s1_o,s1_h,s1_l,s1_c,color = s1_col, wickcolor = s1_col, bordercolor = s1_col, display = s1_tog?display.pane:display.none, title = "Symbol 1 Overlay Candles", editable = false)
    //Label
var s1_lab = label.new(na,na, textcolor = s1_col, style = label.style_label_left, color = invis)
if s1_tog
    s1_lab.set_xy(bar_index+1,math.avg(s1_c,s1_o))
    s1_lab.set_text(get_lab(s1,s1_cv,s1_per,s1_val))

//Symbol 2
    //Candles
plotcandle(s2_o,s2_h,s2_l,s2_c,color = s2_col, wickcolor = s2_col, bordercolor = s2_col, display = s2_tog?display.pane:display.none, title = "Symbol 2 Overlay Candles", editable = false)
    //Label
var s2_lab = label.new(na,na, textcolor = s2_col, style = label.style_label_left, color = invis)
if s2_tog
    s2_lab.set_xy(bar_index+1,math.avg(s2_c,s2_o))
    s2_lab.set_text(get_lab(s2,s2_cv,s2_per,s2_val))

//Symbol 3
    //Candles
plotcandle(s3_o,s3_h,s3_l,s3_c,color = s3_col, wickcolor = s3_col, bordercolor = s3_col, display = s3_tog?display.pane:display.none, title = "Symbol 3 Overlay Candles", editable = false)
    //Label
var s3_lab = label.new(na,na, textcolor = s3_col, style = label.style_label_left, color = invis)
if s3_tog
    s3_lab.set_xy(bar_index+1,math.avg(s3_c,s3_o))
    s3_lab.set_text(get_lab(s3,s3_cv,s3_per,s3_val))

//Period Open
plot(newtf?na:dayo, color = col1, display = show_open?display.all:display.none, style = plot.style_linebr, linestyle = plot.linestyle_dashed, title = "Open Price")

if newtf and show_splits
    line.new(bar_index,low-syminfo.mintick, bar_index,high+syminfo.mintick, extend = extend.both, color = col1, style = line.style_dashed)