Volume MAs Supertrend

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © LyroRS

//@version=6
indicator("Volume MAs Supertrend | Lyro RS", "Volume MAs Supertrend | 𝓛𝔂𝓻𝓸 𝓡𝓢", overlay= true)


// Imports
import TradingView/ta/10 as ta



// Groups
st_g = "𝗦𝗨𝗣𝗘𝗥𝗧𝗥𝗘𝗡𝗗"
ma_g = "𝗠𝗢𝗩𝗜𝗡𝗚 𝗔𝗩𝗘𝗥𝗔𝗚𝗘"
colors_g = '𝗖𝗢𝗟𝗢𝗥𝗦'



// Inputs
st_len = input.int(10, "Supertrend Len", group=st_g, tooltip="Sets the ATR period used in Supertrend calculations. A higher value smooths out signals.")
l_mult = input.float(3.6, "Long Multiplier", step=0.01, minval=0.01, group=st_g, tooltip="Multiplier applied to ATR to calculate the upper Supertrend band (used for long entries).")
s_mult = input.float(1.8, "Short Multiplier", step=0.01, minval=0.01, group=st_g, tooltip="Multiplier applied to ATR to calculate the lower Supertrend band (used for short entries).")



// MA Inputs
MA_Type = input.string("EMA", "Select Moving Average", options=["SMA", "EMA", "WMA", "VWMA", "DEMA", "TEMA", "RMA", "HMA", "ALMA"], group=ma_g, tooltip="Choose the type of volume-adjusted moving average to use in trend calculation.")
MA_len = input.int(12, "Moving Average Length", group=ma_g, tooltip="Length of the selected moving average. Determines how many bars are considered in smoothing the trend.")



// Color Inputs
ColMode = input.string("Mystic", "Custom Color Palette", inline="drop", options=["Classic", "Mystic", "Accented", "Royal"], display=display.none, group=colors_g,  tooltip="Choose a predefined color scheme for indicator visualization.")

cpyn = input.bool(false, "Use Custom Palette", tooltip="Enable manual selection of custom colors for trend signals.", group=colors_g, display=display.none)
cp_UpC = input.color(#00ff00, "Custom Up", inline="Custom Palette", tooltip="Set a custom color for bullish signals.", group=colors_g, display=display.none)
cp_DnC = input.color(#ff0000, "Custom Down", inline="Custom Palette", tooltip="Set a custom color for bearish signals.", group=colors_g, display=display.none)



// Colors
color UpC = na
color DnC = na

switch ColMode
    "Classic" =>
        UpC := #00E676
        DnC := #880E4F
    "Mystic" =>
        UpC := #30FDCF
        DnC := #E117B7
    "Accented" =>
        UpC := #9618F7
        DnC := #FF0078
    "Royal" =>
        UpC := #FFC107
        DnC := #673AB7


if cpyn
    UpC := cp_UpC
    DnC := cp_DnC



// Moving Average Switch
f_mas(MA_len_) =>
    source_ = close
    float ma = na
    switch MA_Type
        "SMA" => ma := ta.sma(source_ * volume, MA_len_) / ta.sma(volume, MA_len_)
        "EMA" => ma := ta.ema(source_ * volume, MA_len_) / ta.ema(volume, MA_len_)
        "WMA" => ma := ta.wma(source_ * volume, MA_len_) / ta.wma(volume, MA_len_)
        "VWMA" => ma := ta.vwma(source_ * volume, MA_len_) / ta.vwma(volume, MA_len_)
        "DEMA" => ma := ta.dema(source_ * volume, MA_len_) / ta.dema(volume, MA_len_)
        "TEMA" => ma := ta.tema(source_ * volume, MA_len_) / ta.tema(volume, MA_len_)
        "RMA" => ma := ta.rma(source_ * volume, MA_len_) / ta.rma(volume, MA_len_)
        "HMA" => ma := ta.hma(source_ * volume, MA_len_) / ta.hma(volume, MA_len_)
        "ALMA" => ma := ta.alma(source_ * volume, MA_len_, 0, 20) / ta.alma(volume, MA_len_, 0, 20)


    ma

// Supertrend Function
Supertrend(atrPeriod) =>
    source = close
    src = f_mas(MA_len)
    atr = ta.atr(atrPeriod)
    u = src + l_mult * atr
    l = src - s_mult * atr
    pl = nz(l[1])
    pu = nz(u[1])

    l := l > pl or source[1] < pl ? l : pl
    u := u < pu or source[1] > pu ? u : pu
    int d = na
    float st = na
    pt = st[1]
    if na(atr[1])
        d := 1
    else if pt == pu
        d := source > u ? -1 : 1
    else
        d := source < l ? 1 : -1
    st := d == -1 ? l : u
    [st, d]


[x, d] = Supertrend(st_len)

st_l = ta.crossunder(d, 0)
st_s = ta.crossover(d, 0)

// Conditions
Long = st_l
Short = st_s


// IF Statement
var color pc = na
if Long and not Short
    pc := UpC


if Short
    pc := DnC



p1 = plot(x, color=pc, title= "Volume MAs Supertrend")
p2 = plot(hl2, display = display.none, editable = false)


fill(p1, p2, hl2, x, na, pc)


barcolor(pc, title= "Coloring Bars")
plotcandle(open, high, low, close, color= pc, wickcolor=pc, bordercolor = pc, force_overlay = true, title= "Plotting Candles", display=display.pane)


// Alerts
alertcondition(Long, "Volume MAs Supertrend - Long", "Volume MAs Supertrend  is Long {{exchange}}:{{ticker}}")
alertcondition(Short, "Volume MAs Supertrend  - Short", "Volume MAs Supertrend  is Short {{exchange}}:{{ticker}}")