Volatility Momentum Score

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © LyroRS

//@version=6
indicator("Volatility Momentum Score | Lyro RS", overlay = false)

//─────────────────────────────────────────────────────────────────────────────────────────────────────────────
//─██████─────────████████──████████─████████████████───██████████████───────████████████████───██████████████─
//─██░░██─────────██░░░░██──██░░░░██─██░░░░░░░░░░░░██───██░░░░░░░░░░██───────██░░░░░░░░░░░░██───██░░░░░░░░░░██─
//─██░░██─────────████░░██──██░░████─██░░████████░░██───██░░██████░░██───────██░░████████░░██───██░░██████████─
//─██░░██───────────██░░░░██░░░░██───██░░██────██░░██───██░░██──██░░██───────██░░██────██░░██───██░░██─────────
//─██░░██───────────████░░░░░░████───██░░████████░░██───██░░██──██░░██───────██░░████████░░██───██░░██████████─
//─██░░██─────────────████░░████─────██░░░░░░░░░░░░██───██░░██──██░░██───────██░░░░░░░░░░░░██───██░░░░░░░░░░██─
//─██░░██───────────────██░░██───────██░░██████░░████───██░░██──██░░██───────██░░██████░░████───██████████░░██─
//─██░░██───────────────██░░██───────██░░██──██░░██─────██░░██──██░░██───────██░░██──██░░██─────────────██░░██─
//─██░░██████████───────██░░██───────██░░██──██░░██████─██░░██████░░██───────██░░██──██░░██████─██████████░░██─
//─██░░░░░░░░░░██───────██░░██───────██░░██──██░░░░░░██─██░░░░░░░░░░██───────██░░██──██░░░░░░██─██░░░░░░░░░░██─
//─██████████████───────██████───────██████──██████████─██████████████───────██████──██████████─██████████████─
//─────────────────────────────────────────────────────────────────────────────────────────────────────────────
//                                                 LyroRS v1.0


// Libraries
import LyroRS/LMAs/1 as DynamicMAs   // Import custom library for dynamic moving averages


// Groups for input organization
vms_g = "𝗩𝗢𝗟𝗔𝗧𝗜𝗟𝗜𝗧𝗬 𝗠𝗢𝗠𝗘𝗡𝗧𝗨𝗠 𝗦𝗖𝗢𝗥𝗘"
sdb_g = "𝗦𝗗 𝗕𝗔𝗡𝗗𝗦"
display_g = '𝗗𝗜𝗦𝗣𝗟𝗔𝗬'


// Inputs

// -- Volatility Momentum Score
len1  = input.int(35, "Price Z Length", group=vms_g, tooltip="Sets the lookback length used for calculating the Price Z score.")
len2  = input.int(35, "Volatility Z Length", group=vms_g, tooltip="Sets the lookback length used for calculating the Volatility Z score.")

// -- SD Bands
len3  = input.int(100, "Band Length", group=sdb_g, tooltip="Defines the number of bars used to calculate the standard deviation bands.")
pmult = input.float(1.5, "+ Band Multiplier", group=sdb_g, minval=0.001, tooltip="Adjusts the positive (upper) band distance from the mean; higher values place the band further away.")
nmult = input.float(-0.4, "- Band Multiplier", group=sdb_g, maxval=-0.001, tooltip="Adjusts the negative (lower) band distance from the mean; smaller values place the band further away.")

// -- Color Inputs
signal_type = input.string("Trend", "Select Signal Type", options=["Trend", "Reversion"], group=display_g, tooltip="Select which way to use the indicator.")
d_signs           = input.bool  (true,             "Display Signs", group= display_g, display=display.none, tooltip="Enables signs for Trend mode.")
d_bgcol           = input.bool  (true,             "", group= display_g, display=display.none, tooltip="Enables background color for Reversion & Valuation mode.", inline= "bgcol")
d_obos_sigs           = input.bool  (true,             "Display Oversold/Overbought Signs", group= display_g, display=display.none, tooltip="Enables triangle signs to be displayed.")
bgTransp = input.int(70, "Background Transparency", group=display_g, tooltip="Adjusts how transparent the background color appears on the chart, where 0 is fully visible and 100 is fully transparent.", inline= "bgcol")


ColMode = input.string("Mystic", "Custom Color Palette", inline="drop", options=["Classic", "Mystic", "Accented", "Royal"], display=display.none, group=display_g,  tooltip="Choose a predefined color scheme for indicator visualization.")

cpyn = input.bool(true, "Use Custom Palette", tooltip="Enable manual selection of custom colors for trend signals.", group=display_g, display=display.none)
cp_UpC = input.color(#00ff00, "Custom Up", inline="Custom Palette", tooltip="Set a custom color for bullish signals.", group=display_g, display=display.none)
cp_DnC = input.color(#ff0000, "Custom Down", inline="Custom Palette", tooltip="Set a custom color for bearish signals.", group=display_g, display=display.none)


// Colors
color UpC = na
color DnC = na

switch ColMode
    "Classic" =>
        UpC := #00E676
        DnC := #880E4F
    "Mystic" =>
        UpC := #30FDCF
        DnC := #E117B7
    "Accented" =>
        UpC := #9618F7
        DnC := #FF0078
    "Royal" =>
        UpC := #FFC107
        DnC := #673AB7

if cpyn
    UpC := cp_UpC
    DnC := cp_DnC


// Function: calculate z-score of a series
zscore(src, len) =>
    x = src
    h = DynamicMAs.EMA(src, len)   // mean via EMA
    o = ta.stdev(src, len)         // standard deviation
    (x - h) / o                    // z-score


// Calculate z-scores for price and volatility
price_z      = zscore(close, len1)
volatility_z = zscore(ta.stdev(close, len2), len2)

// Average of price & volatility z-scores
avg  = math.avg(price_z, volatility_z)

// Standard deviation bands
std          = ta.stdev(avg, len3)
std2         = ta.stdev(avg, len3)
upperBand = std * pmult 
lowerBand = std2 * nmult

// Persistent color variables
color pc  = na   // background color
var color pc2 = na   // plot color
var color pc3 = na // Candle Color
var int signal = 0

color.new(DnC, bgTransp)
// BG Color logic
if avg > upperBand
    pc := color.new(DnC, bgTransp)

else if avg < lowerBand
    pc := color.new(UpC, bgTransp)


// Line Color logic: based on band position
if avg > upperBand
    pc2 := UpC
else if avg < lowerBand
    pc2 := DnC


// Candle Color logic: cross above/below bands
if ta.crossover(avg, upperBand)
    pc3 := UpC
    signal := 1

else if ta.crossunder(avg, lowerBand)
    pc3 := DnC
    signal := -1



// Plots
pa = plot(avg, color=pc2, title="Average Zscore")

pup = plot(upperBand, color=UpC)
plb = plot(lowerBand, color=DnC)
plotcandle(open, high, low, close, "Candle Color", pc3, pc3, true, bordercolor = pc3, display = display.pane, force_overlay = true)

bgcolor(force_overlay=true, color=signal_type == "Reversion" ? pc : na, editable = false)


fill(pa, pup, avg, upperBand, signal == 1 ? color.new(UpC, 30) : na, color.new(chart.bg_color, 50), display= display.all)
fill(pa, plb, avg, lowerBand, signal == -1 ? color.new(DnC, 30) : na, color.new(chart.bg_color, 50), display= display.all)


// Labels
plotshape(ta.crossover(signal, 0), title="Buy Signal", location=location.belowbar,
           style=shape.labelup, text="𝓛𝓸𝓷𝓰", textcolor=#000000, size=size.small,
           color=UpC, force_overlay=true, display= signal_type == "Trend" and d_signs == true ? display.pane : display.none)

plotshape(ta.crossunder(signal, 0), title="Sell Signal", location=location.abovebar,
           style=shape.labeldown, text="𝓢𝓱𝓸𝓻𝓽", textcolor=#000000, size=size.small,
           color=DnC, force_overlay=true, display= signal_type == "Trend" and d_signs == true ? display.pane : display.none) 




plotchar(upperBand + 0.5, char='▼', color= ta.crossunder(avg, upperBand) ? DnC : na, location=location.absolute, title= "Overbought Signal", display= d_obos_sigs ?  display.pane : display.none, size= size.tiny)
plotchar(lowerBand - 0.5, char='▲', color= ta.crossover(avg, lowerBand) ? UpC : na, location=location.absolute, title= "Oversold Signal", display= d_obos_sigs ?  display.pane : display.none, size= size.tiny)