Three Bar Reversal Pattern

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © ActiveQuants
// Created by ActiveQuants
// Last updated: March 6, 2025

//@version=6
indicator(title = "Three Bar Reversal Pattern [ActiveQuants]", shorttitle = "3 Bar Reversal Pattern [ActiveQuants]", overlay = true, max_labels_count = 500)
import MarcosACH/CandleAnalysis/1 as CndlA

//#region ------ USER INPUTS
bool plotBullishPattern = input.bool(defval = true, title = "Bullish Pattern", inline = "bullish pattern")
bool plotBearishPattern = input.bool(defval = true, title = "Bearish Pattern", inline = "bearish pattern")
color bullishPatternColor = input.color(defval = #089981, title = "", inline = "bullish pattern")
color bearishPatternColor = input.color(defval = #ff5252, title = "", inline = "bearish pattern")
string bullishPatternSize = input.string(defval = size.normal, title = "", options = [size.auto, size.tiny, size.small, size.normal, size.large, size.huge], inline = "bullish pattern")
string bearishPatternSize = input.string(defval = size.normal, title = "", options = [size.auto, size.tiny, size.small, size.normal, size.large, size.huge], inline = "bearish pattern")
int showLast = input.int(defval = 500, title = "Show Last", minval = 10, step = 10, tooltip = "Number of bars back the indicator can plot.")

// Filters
bool enableVolumeSmaFilter = input.bool(defval = true, title = "Volume SMA Filter", tooltip = "If enabled, this function will remove patterns where the volume of the last candle is below the volume SMA.", group = "Filters")
int volSmaLength = input.int(defval = 20, title = "Volume SMA Length", minval = 1, group = "Filters")
float shootingStarBodyLimit = input.float(defval = 0.5, title = "Shooting Star Body Limit", minval = 0, maxval = 1, step = 0.01, 
 tooltip = "This parameter defines the percentage of the candle's range used to classify a Shooting Star candle (e.g., if this parameter is set to 0.5, then any candle whose body is entirely located in the lower 50% of its range will be identified as a Shooting Star). If a Shooting Star is identified within a bullish pattern, that pattern will be discarded (set this parameter to 0 if you don't want to apply this filter).", 
 group = "Filters")
float hammerBodyLimit = input.float(defval = 0.5, title = "Hammer Body Limit", minval = 0, maxval = 1, step = 0.01, 
 tooltip = "This parameter defines the percentage of the candle's range used to classify a Hammer candle (e.g., if this parameter is set to 0.5, then any candle whose body is entirely located in the upper 50% of its range will be identified as a Hammer). If a Hammer is identified within a bearish pattern, that pattern will be discarded (set this parameter to 0 if you don't want to apply this filter).", 
 group = "Filters")
bool enableMidCandleFilter = input.bool(defval = false, title = "Middle Candle Filter", 
 tooltip = "If enabled, this function will remove bullish signals where the low of the middle candle is not lower than both the first and last candles' lows, and it will remove bearish signals where the high of the middle candle is not higher than both the first and last candles' highs.", group = "Filters")
bool enableRsiFilter = input.bool(defval = false, title = "RSI Filter", 
 tooltip = "If enabled, this function will remove bullish signals where the RSI is not oversold, and it will remove bearish signals where the RSI is not overbought.", group = "Filters")
int rsiLength = input.int(defval = 14, title = "RSI Length", minval = 1, group = "Filters")
int rsiOverboughtThreshold = input.int(defval = 60, title = "Overbought Threshold", minval = 1, group = "Filters")
int rsiOversoldThreshold = input.int(defval = 40, title = "Oversold Threshold", minval = 1, group = "Filters")
//#endregion

//#region ----- CALCULATIONS
float volSma = ta.sma(volume, volSmaLength)
bool bullish = CndlA.isBearish(2) and CndlA.isBearish(1) and close > open[2] and not CndlA.isShootingStar(fib = shootingStarBodyLimit) and barstate.isconfirmed
bool bearish = CndlA.isBullish(2) and CndlA.isBullish(1) and close < open[2] and not CndlA.isHammer(fib = hammerBodyLimit) and barstate.isconfirmed

if enableVolumeSmaFilter and volume < volSma
    bullish := false
    bearish := false

if enableMidCandleFilter
    if bullish and low[1] > low[2] or low[1] > low
        bullish := false
    if bearish and high[1] < high[2] or high[1] < high
        bearish := false

bool rsiOverbought = ta.rsi(close, rsiLength) > rsiOverboughtThreshold
bool rsiOversold = ta.rsi(close, rsiLength) < rsiOversoldThreshold

if enableRsiFilter
    if bullish and not rsiOversold
        bullish := false
    if bearish and not rsiOverbought
        bearish := false
//#endregion

//#region ------ VARIABLES
var array<label> labels = array.new_label()
//#endregion

//#region ----- PLOTTING
if bullish and plotBullishPattern
    label pattern = label.new(bar_index, close, "▲", yloc = yloc.belowbar, color = na, style = label.style_triangleup, textcolor = bullishPatternColor, size = bullishPatternSize)
    array.push(labels, pattern)
else if bearish and plotBearishPattern
    label pattern = label.new(bar_index, close, "▼", yloc = yloc.abovebar, color = na, style = label.style_triangledown, textcolor = bearishPatternColor, size = bearishPatternSize)
    array.push(labels, pattern)

if array.size(labels) > 0
    for i = array.size(labels) - 1 to 0
        label currentLabel = array.get(labels, i)
        if label.get_x(currentLabel) < bar_index - showLast
            label.delete(currentLabel)
            array.remove(labels, i)
//#endregion

//#region ----- ALERTS
alertcondition(bullish, title = "Bullish Reversal Pattern", message = "Bullish Reversal Pattern detected")
alertcondition(bearish, title = "Bearish Reversal Pattern", message = "Bearish Reversal Pattern detected")
//#endregion