skipp_indicators

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © preuss_steffen

//@version=6
library("skipp_indicators", overlay = true)
// Last refreshed: 2026-07-03

// --------------------------------------------------
// Zero-lag EMA variants
// --------------------------------------------------

// @function Double-EMA zero-lag source
export zl_src(series float src, simple int len) =>
    float e1 = ta.ema(src, len)
    float e2 = ta.ema(e1, len)
    2.0 * e1 - e2

// @function Zero-lag with lead percentage
export zl_src_pct(series float _src, simple int _len, float _pct) =>
    int lag = math.max(1, int(math.floor((_len - 1) / 2)))
    float lead = na(_src) or na(_src[lag]) ? na : (_src - _src[lag])
    float k = float(_pct) / 100.0
    float out = na(lead) ? _src : (_src + k * lead)
    out

// @function Zero-lag trend core (EMA + aggression blend)
export zl_trend_core(series float _src, simple int _len, float _aggr) =>
    float emaBase = ta.ema(_src, _len)
    float zlBase  = zl_src(_src, _len)
    na(zlBase) ? emaBase : (emaBase + _aggr * (zlBase - emaBase))

// --------------------------------------------------
// Log regression
// --------------------------------------------------

// @function Single-window log regression slope
export log_regression_single(series float src, simple int length) =>
    if length < 2
        0.0
    else
        float sumX    = 0.0
        float sumY    = 0.0
        float sumXSqr = 0.0
        float sumXY   = 0.0
        bool failed   = false
        for i = 0 to length - 1
            float v = src[i]
            if na(v) or v <= 0.0
                failed := true
                break
            float val = math.log(v)
            float per = i + 1.0
            sumX    += per
            sumY    += val
            sumXSqr += per * per
            sumXY   += val * per
        if failed
            float(na)
        else
            float slope = (length * sumXY - sumX * sumY) / (length * sumXSqr - sumX * sumX)
            slope * -1.0

// @function Multi-window averaged regression slope oscillator
export calc_reg_slope_osc(series float src, simple int minR, simple int maxR, simple int stepV) =>
    float slopeSum  = 0.0
    int   slopeCount = 0
    for i = minR to maxR by stepV
        float res = log_regression_single(src, i)
        if not na(res)
            slopeSum  += res
            slopeCount += 1
    slopeCount > 0 ? slopeSum / slopeCount : 0.0