Pattern Trade Levels

//@version=5
// Pattern Trade Levels — companion to scripts/pattern_scan.py (issue #348).
// Type in the boundary and pattern low from any chart pattern; draws
// confirm (+3%), measured-move target, both stop conventions, and an R:R table.
// Levels are drawn as hand-built long-dash segments (Pine's style_dashed is a
// fixed micro-dash; the drawing-tool look needs manual segments).
indicator("Pattern Trade Levels", overlay = true, max_lines_count = 500, max_labels_count = 20)

B        = input.float(0.0,   "Boundary / breakout level (B)",            step = 0.01)
L        = input.float(0.0,   "Pattern low (L)",                          step = 0.01)
S        = input.float(0.0,   "Structural stop (last higher low, 0=off)", step = 0.01)
confPct  = input.float(3.0,   "Confirm / negation buffer %",              step = 0.1, minval = 0)
useLog   = input.bool(true,   "Log measured move (BxB/L) — off = B+(B-L)")
entryOpt = input.string("Confirm", "Entry for R:R", options = ["Confirm", "Boundary", "Current price"])
dashOn   = input.int(6, "Dash length (bars)",  minval = 1, group = "Style")
dashOff  = input.int(5, "Dash gap (bars)",     minval = 1, group = "Style")
spanBack = input.int(260, "Extend left (bars)", minval = 20, maxval = 5000, group = "Style")
spanFwd  = input.int(30, "Extend right (bars)", minval = 0, maxval = 400, group = "Style")

confirm  = B * (1 + confPct / 100)          // daily close above = validated breakout
negStop  = B * (1 - confPct / 100)          // close back below after breakout = failed
target   = useLog ? B * B / L : B + (B - L)
entry    = entryOpt == "Confirm" ? confirm : entryOpt == "Boundary" ? B : close
stopUsed = S > 0 ? S : negStop
rr       = entry - stopUsed > 0 ? (target - entry) / (entry - stopUsed) : na

var lvlLines  = array.new<line>()
var lvlLabels = array.new<label>()

f_clear() =>
    while array.size(lvlLines) > 0
        line.delete(array.pop(lvlLines))
    while array.size(lvlLabels) > 0
        label.delete(array.pop(lvlLabels))

f_lvl(float y, color col, string txt) =>
    i = math.max(0, bar_index - spanBack)
    rightEdge = bar_index + spanFwd
    // At most 95 segments per level keeps all five levels below 500 IDs.
    spacing = math.max(dashOn + dashOff, int(math.ceil((rightEdge - i) / 95.0)))
    while i < rightEdge
        array.push(lvlLines, line.new(i, y, math.min(i + dashOn, rightEdge), y, color = col, width = 1,
                                      style = line.style_solid))
        i += spacing
    array.push(lvlLabels, label.new(bar_index - 30, y,
               txt + "  " + str.tostring(y, format.mintick),
               color = color.new(color.black, 100), textcolor = col,
               style = label.style_none, size = size.normal))

if barstate.islast
    f_clear()
if barstate.islast and B > 0 and L > 0 and L < B
    f_lvl(B,       color.fuchsia, "boundary")
    f_lvl(confirm, color.aqua,    "confirm +" + str.tostring(confPct, "#.#") + "%")
    f_lvl(target,  color.lime,    "target")
    f_lvl(negStop, color.orange,  "negation stop")
    if S > 0
        f_lvl(S, color.red, "structural stop")

    var table t = table.new(position.top_right, 2, 5, bgcolor = color.new(color.black, 20))
    table.cell(t, 0, 0, "Entry (" + entryOpt + ")", text_color = color.gray,  text_size = size.small)
    table.cell(t, 1, 0, str.tostring(entry, format.mintick),  text_color = color.white, text_size = size.small)
    table.cell(t, 0, 1, "Target",                  text_color = color.gray,  text_size = size.small)
    table.cell(t, 1, 1, str.tostring(target, format.mintick) + "  (+" + str.tostring((target / entry - 1) * 100, "#.#") + "%)",
               text_color = color.lime,  text_size = size.small)
    table.cell(t, 0, 2, "Stop",                    text_color = color.gray,  text_size = size.small)
    table.cell(t, 1, 2, str.tostring(stopUsed, format.mintick) + "  (-" + str.tostring((1 - stopUsed / entry) * 100, "#.#") + "%)",
               text_color = color.orange, text_size = size.small)
    table.cell(t, 0, 3, "R : R",                   text_color = color.gray,  text_size = size.small)
    table.cell(t, 1, 3, na(rr) ? "n/a" : str.tostring(rr, "#.##") + "R",
               text_color = rr >= 2 ? color.lime : color.red, text_size = size.small)
    table.cell(t, 0, 4, "Dist to confirm",         text_color = color.gray,  text_size = size.small)
    table.cell(t, 1, 4, str.tostring((confirm / close - 1) * 100, "#.##") + "%",
               text_color = color.white, text_size = size.small)

alertcondition(B > 0 and ta.crossover(close, confirm), "Confirm breakout",
               "Price crossed above the confirm level — breakout validated")
alertcondition(B > 0 and ta.crossover(close, B), "Boundary touch",
               "Price crossed above the pattern boundary")