MTF Supply/Demand v2

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © goodgains


//@version=5
indicator("MTF Supply/Demand v2",  overlay = true, max_labels_count = 500, max_boxes_count = 500, max_lines_count = 500, max_bars_back = 1000)

// @keywords: multi-timeframe-zones, supply-demand-boxes, break-of-structure, pivot-swing-length, atr-zone-thickness, mtf-security-call, zone-labels, demand-supply-levels, overlap-control, instructions-label, higher-tf-levels, zone-extension, bos-detection, poi-zones, swing-pivots, chart-overlay-zones, historical-boxes, zone-management, liquidity-zones, structure-break

//--INSTRUCTIONS--//
var label instruction_label = na
instructions_tooltip = "• Supply/Demand = zones where buyers or sellers will look to enter the market.
  "

instructions = input.bool(title='Show Instructions', defval=false, inline='1', tooltip = instructions_tooltip)
if barstate.islast and instructions
    if not na(instruction_label[1])
        label.delete(instruction_label[1])
    instruction_label := label.new(bar_index + 5, close, instructions_tooltip, xloc = xloc.bar_index , yloc = yloc.price, color = color.black , style = label.style_label_left, textcolor = color.white, size = size.large, textalign = text.align_left) 
//--INSTRUCTIONS--//


//--SUPPLY DEMAND INPUTS--//
sd_length = input.int(10, title = 'Supply/Demand Length', group = 'Supply/Demand Settings', minval = 3, maxval = 50)
sd_width = input.float(7.00, title = 'Supply/Demand Width', group = 'Supply/Demand Settings', minval = 1, maxval = 15, step = 0.5)

supply_color = input.color(color.new(#c30616,70), title = 'Supply', group = 'Supply/Demand Settings', inline = '3')
demand_color = input.color(color.new(#05cd0e,70), title = 'Demand', group = 'Supply/Demand Settings', inline = '3')
sd_labelcolor = input.color(color.new(color.white,20), title = 'Label', group = 'Supply/Demand Settings', inline = '3')

show_supplydemand1 = input.bool(true, title = 'Chart Supply Demand Zones', group = 'Supply/Demand Settings', inline = '4')
_sd_1 = input.bool(false, title = 'Create Zones for 1 Minutes', group = 'Supply/Demand Settings', inline = '5')
_sd_5 = input.bool(false, title = 'Create Zones for 5 Minutes', group = 'Supply/Demand Settings', inline = '6')

_allow_overlap = input.bool(true, title = 'Allow Zones to Overlap', group = 'Supply/Demand Settings', inline = '14')
//--SUPPLY DEMAND INPUTS--//


//--PRICE ACTION INPUTS--//
show_priceaction = input.bool(false, title = 'Price Action Labels', group = 'Price Action Label Settings', inline = '0', tooltip = 'Price Action Labels mark at each swing high or swing low. \n\nHH = Higher High \nLH = Lower High \nLL=
 Lower Low \nLH = Lower High')
pa_color = input.color(color.new(color.white, 60), title = 'Label', group = 'Price Action Label Settings', inline = '1')
//--PRICE ACTION INPUTS--//


//-----FUNCTIONS-----//
//--FUNCTION TO ADD NEW AND REMOVE LAST IN ARRAY--//
f_array_add_pop(array, new_value_to_add) =>
    array.unshift(array, new_value_to_add)
    array.pop(array)


//--FUNCTION SWING H & L LABELS--//
f_sh_sl_labels(current, previous, swing_type) =>

    var string label_text = na
    if swing_type == 1
        if current >= previous
            label_text := 'HH'
        else
            label_text := 'LH'
        label.new(bar_index - sd_length, current, text = label_text, style=label.style_label_down, textcolor = pa_color, color = color.new(pa_color, 100), size = size.tiny, tooltip = label_text)
    
    else if swing_type == -1
        if current >= previous
            label_text := 'HL'
        else
            label_text := 'LL'
        label.new(bar_index - sd_length, current, text = label_text, style=label.style_label_up, textcolor = pa_color, color = color.new(pa_color, 100), size = size.tiny, tooltip = label_text)



//--FUNCTION MAKE SURE SUPPLY ISNT OVERLAPPING--//
f_check_overlapping(new_poi, box_array, atr) =>

    atr_threshold = atr * 2
    okay_to_draw = true

    for i = 0 to array.size(box_array) - 1
        top = box.get_top(array.get(box_array, i))
        bottom = box.get_bottom(array.get(box_array, i))
        poi = (top + bottom) / 2

        upper_boundary = poi + atr_threshold
        lower_boundary = poi - atr_threshold

        if new_poi >= lower_boundary and new_poi <= upper_boundary
            okay_to_draw := false
            break
        else 
            okay_to_draw := true
    okay_to_draw



// function to get swing h/l, previous swing h/l, and tell trend
f_get_swing_values(use_tf, sd_length) =>

    var float sh = na
    var float sl = na
    var float csh = na
    var float csl = na
    var int csh_time = na
    var int csl_time = na
    var float atr = na

    if use_tf 
        sh := ta.pivothigh(high, sd_length, sd_length)
        sl := ta.pivotlow(low, sd_length, sd_length)

        csh := ta.valuewhen(ta.pivothigh(high, sd_length, sd_length), high[sd_length], 0)
        csl := ta.valuewhen(ta.pivotlow(low, sd_length, sd_length), low[sd_length], 0)

        csh_time := ta.valuewhen(ta.pivothigh(high, sd_length, sd_length), time[sd_length], 0)
        csl_time := ta.valuewhen(ta.pivotlow(low, sd_length, sd_length), time[sd_length], 0)

        atr := ta.atr(50)

    [sh, sl, csh, csl, csh_time, csl_time, atr]



//--FUNCTION TO DRAW SUPPLY OR DEMAND ZONE--//
f_supply_demand(box_array, box_type, atr, box_left, level, str_text) =>

    atr_buffer = atr * (sd_width / 10)
    box_right = time

    var float box_top = 0.00
    var float box_bottom = 0.00
    var float poi = 0.00
    var bool new_supply_or_demand = false

    if box_type == 1
        box_top := level
        box_bottom := box_top - atr_buffer
        poi := (box_top + box_bottom) / 2
    else if box_type == -1
        box_bottom := level
        box_top := box_bottom + atr_buffer
        poi := (box_top + box_bottom) / 2

    // okay_to_draw = f_check_overlapping(poi, box_array, atr)
    okay_to_draw = true
    if okay_to_draw
        new_supply_or_demand := true

        //delete oldest box, and then create a new box and add it to the array
        if box_type == 1 
            box.delete( array.get(box_array, array.size(box_array) - 1) )
            f_array_add_pop(box_array, box.new( left = box_left, top = box_top, right = box_right, bottom = box_bottom,
             border_color = supply_color, border_width = 0, bgcolor = supply_color, extend = extend.right,
             text =str_text, text_halign = text.align_right, text_valign = text.align_center, 
             text_color = sd_labelcolor, text_size = size.small, xloc = xloc.bar_time, border_style = line.style_solid))
        
        else if box_type == -1
            box.delete( array.get(box_array, array.size(box_array) - 1) )
            f_array_add_pop(box_array, box.new( left = box_left, top = box_top, right = box_right, bottom = box_bottom,
             border_color = demand_color , border_width = 0, bgcolor = demand_color , extend = extend.right,
             text =str_text, text_halign = text.align_right, text_valign = text.align_center, 
             text_color = sd_labelcolor, text_size = size.small, xloc = xloc.bar_time, border_style = line.style_solid))
    



//--FUNCTION TO CHANGE SUPPLY/DEMAND TO A BOS IF BROKEN--// (THIS VERSION WE JUST DELETE)
f_sd_to_bos(box_array, bos_array, zone_type) =>
    for i = 0 to array.size(box_array) - 1
        level_to_break = zone_type == 1 ? box.get_top(array.get(box_array,i)) : box.get_bottom(array.get(box_array,i))
        if (zone_type == 1  and close >= level_to_break) or (zone_type == -1  and close <= level_to_break) 
            box.delete(array.get(box_array, i))



//--FUNCTION MANAGE CURRENT BOXES BY CHANGING ENDPOINT--//
f_extend_box_endpoint(box_array) =>
    for i = 0 to array.size(box_array) - 1
        box.set_right(array.get(box_array, i), time + (timeframe.in_seconds() * 1000 * 100))

//-----FUNCTIONS END-----//












//-----DEFINE VARIABLES-----//

//--ARRAYS FOR SWING H/L & BN--//
var current_supply_box = array.new_box(25, na)
var current_demand_box = array.new_box(25, na)

var supply_box1 = array.new_box(20, na)
var demand_box1 = array.new_box(20, na)
var supply_box5 = array.new_box(20, na)
var demand_box5 = array.new_box(20, na)

//--ARRAYS FOR SWING H/L & BN--//


//--ARRAYS FOR BOS--//
var supply_bos = array.new_box(5, na)
var demand_bos = array.new_box(5, na)
//--ARRAYS FOR BOS--//
//-----DEFINE VARIABLES-----//



//-----START CALCULATING-----//
[sh, sl, csh, csl, csh_time, csl_time, atr] = request.security(syminfo.ticker, "", f_get_swing_values(true, sd_length))


[sh1, sl1, csh1, csl1, csh_time1, csl_time1, atr1] = 
 request.security(syminfo.ticker, "1", f_get_swing_values(_sd_1, sd_length), lookahead = barmerge.lookahead_on )
[sh5, sl5, csh5, csl5, csh_time5, csl_time5, atr5] = 
 request.security(syminfo.ticker, "5", f_get_swing_values(_sd_5, sd_length), lookahead = barmerge.lookahead_on )


// draw price action labels for current chart
var float psh = na
var float psl = na
psh := not na(sh) ? csh[1] : psh[1]
psl := not na(sl) ? csl[1] : psl[1]

if show_priceaction
    if not na(sh) 
        f_sh_sl_labels(csh, psh, 1)
    else if not na(sl)
        f_sh_sl_labels(csl, psl, -1)


// draw supply/demands
if show_supplydemand1
    if not na(sh) 
        f_supply_demand(current_supply_box, 1, atr, csh_time, csh, "")
    if not na(sl) 
        f_supply_demand(current_demand_box, -1, atr, csl_time, csl, "")

if _sd_1 and timeframe.in_seconds() <= timeframe.in_seconds("1")
    if na(sh1) and not na(sh1[1]) 
        f_supply_demand(supply_box1, 1, atr1, csh_time1, csh1, "1min")
    if na(sl1) and not na(sl1[1]) 
        f_supply_demand(demand_box1, -1, atr1, csl_time1, csl1, "1min")

if _sd_5 and timeframe.in_seconds() <= timeframe.in_seconds("5")
    if na(sh5) and not na(sh5[1]) 
        f_supply_demand(supply_box5, 1, atr5, csh_time5, csh5, "5min")
    if na(sl5) and not na(sl5[1]) 
        f_supply_demand(demand_box5, -1, atr5, csl_time5, csl5, "5min")



// bar_mult = timeframe.in_seconds("30") / timeframe.in_seconds() 
// bgcolor(not na(sh30) ? color.new(color.red,50) : not na(sl30) ? color.new(color.green,50) : na, offset = -sd_length * bar_mult)




// move s/d zones to bos
f_sd_to_bos(current_supply_box, supply_bos, 1)
f_sd_to_bos(current_demand_box, demand_bos, -1)

f_sd_to_bos(supply_box1, supply_bos, 1)
f_sd_to_bos(demand_box1, demand_bos, -1)

f_sd_to_bos(supply_box5, supply_bos, 1)
f_sd_to_bos(demand_box5, demand_bos, -1)






// extend lines
if barstate.islast

    f_extend_box_endpoint(current_supply_box)
    f_extend_box_endpoint(current_demand_box)

    f_extend_box_endpoint(supply_box1)
    f_extend_box_endpoint(demand_box1)

    f_extend_box_endpoint(supply_box5)
    f_extend_box_endpoint(demand_box5)