MACD VWMA Strategy

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © goodgains


//@version=5
indicator("MACD VWMA Strategy", overlay = true)

// @keywords: macd-crossover, vwma-trend, supertrend-filter, mtf-supertrend, atr-trailing-stop, buy-sell-shapes, histogram-macd, signal-line-cross, oscillator-ma-type, overlay-signals, fast-slow-macd, security-higher-tf, filter-gated-entries, directional-bias, alert-conditions, trend-confirmation, dual-filter, intraday-signals, momentum-cross, entry-markers

// supertrend settings
use_supertrend      = input.bool(true, title = 'Supertrend Filter', group = 'Supertrend Settings', inline = 'ST')
st_timeframe        = input.timeframe("15", title = '', group = 'Supertrend Settings', inline = 'ST 2')
st_atrPeriod        = input.int(10,    "Length", minval = 1, group = 'Supertrend Settings', inline = 'ST 2')
st_factor           = input.float(3.0, "Factor",     minval = 0.01, step = 0.01, group = 'Supertrend Settings', inline = 'ST 2')



// macd settings
macd_src        = input(title="Source", defval=close, group = 'MACD Settings', inline = 'MACD')
fast_length     = input(title="Fast Length", defval=12, group = 'MACD Settings', inline = 'MACD')
slow_length     = input(title="Slow Length", defval=26, group = 'MACD Settings', inline = 'MACD')
signal_length   = input.int(title="Signal Smoothing",  minval = 1, maxval = 50, defval = 9, group = 'MACD Settings', inline = 'MACD')
sma_source      = input.string(title="Oscillator MA Type",  defval="EMA", options=["SMA", "EMA"], group = 'MACD Settings', inline = 'MACD')
sma_signal      = input.string(title="Signal Line MA Type", defval="EMA", options=["SMA", "EMA"], group = 'MACD Settings', inline = 'MACD')



// calculate supertrend
pine_supertrend(factor, atrPeriod) =>
    src = hl2
    atr = ta.atr(atrPeriod)
    upperBand = src + factor * atr
    lowerBand = src - factor * atr
    prevLowerBand = nz(lowerBand[1])
    prevUpperBand = nz(upperBand[1])

    lowerBand := lowerBand > prevLowerBand or close[1] < prevLowerBand ? lowerBand : prevLowerBand
    upperBand := upperBand < prevUpperBand or close[1] > prevUpperBand ? upperBand : prevUpperBand
    int direction = na
    float superTrend = na
    prevSuperTrend = superTrend[1]
    if na(atr[1])
        direction := 1
    else if prevSuperTrend == prevUpperBand
        direction := close > upperBand ? -1 : 1
    else
        direction := close < lowerBand ? 1 : -1
    superTrend := direction == -1 ? lowerBand : upperBand
    [superTrend[1], direction[1]]


[supertrend, direction] = request.security(syminfo.tickerid, st_timeframe, pine_supertrend(st_factor, st_atrPeriod), lookahead = barmerge.lookahead_on)
supertrend := barstate.isfirst ? na : supertrend
upTrend =    plot(direction < 0 ? supertrend : na, "Up Trend",   color = color.rgb(0, 0, 0), style = plot.style_linebr, display = use_supertrend ? display.all : display.none)
downTrend =  plot(direction < 0 ? na : supertrend, "Down Trend", color = color.rgb(0, 0, 0),   style = plot.style_linebr, display = use_supertrend ? display.all : display.none)
bodyMiddle = plot(barstate.isfirst ? na : (open + close) / 2, "Body Middle",display = display.none)

fill(bodyMiddle, upTrend,   color.new(color.blue, 90), fillgaps = false, display = use_supertrend ? display.all : display.none)
fill(bodyMiddle, downTrend, color.new(#000000, 90), fillgaps = false, display = use_supertrend ? display.all : display.none)



// calculate MACD
fast_ma = sma_source == "SMA" ? ta.sma(macd_src, fast_length) : ta.ema(macd_src, fast_length)
slow_ma = sma_source == "SMA" ? ta.sma(macd_src, slow_length) : ta.ema(macd_src, slow_length)
macd = fast_ma - slow_ma
signal = sma_signal == "SMA" ? ta.sma(macd, signal_length) : ta.ema(macd, signal_length)
hist = macd - signal



// calculate signals
st_Buy      = direction < 0 or not use_supertrend
st_Sell     = direction >= 0 or not use_supertrend

macdBuy     = signal < 0 and ta.crossover(hist, 0)
macdSell    = signal > 0 and ta.crossunder(hist, 0)

buyCond     = st_Buy and macdBuy
sellCond    = st_Sell and macdSell

plotshape(buyCond, title = 'Buy', style = shape.triangleup, color = color.black, size = size.small, location = location.belowbar)
plotshape(sellCond, title = 'Sell', style = shape.triangledown, color = color.black, size = size.small, location = location.abovebar)

alertcondition(buyCond, title = 'Buy Signal', message = 'Buy Signal')
alertcondition(sellCond, title = 'Sell Signal', message = 'Sell Signal')