Liquidity Zones

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © ActiveQuants
// Created by ActiveQuants
// Last updated: March 15, 2025

//@version=6
indicator(title = "Liquidity Zones [ActiveQuants]", overlay = true, max_labels_count = 500)
import MarcosACH/CandleAnalysis/1 as CndlA

//#region ------ USER INPUTS
color liquidityZonesColor = input.color(defval = color.new(color.orange, 70), title = "Liquidity Zones Color")
int volLength = input.int(defval = 20, title = "Volume SMA Length")
float volMultiplier = input.float(defval = 2.0, title = "Volume Threshold Multiplier", tooltip = "This multiplies the volume SMA.")
int volatilityLength = input.int(defval = 14, title = "Price Std. Dev. Length", tooltip = "Length for calculating the closing price standard deviation, used to measure average volatility.")
bool plotZoneVolume = input.bool(defval = true, title = "Zone Volume", inline = "volume")
string volumeMeasurement = input.string(defval = "Units", title = "", options = ["Units", "Currency Value"], inline = "volume")
string volumeLabelSize = input.string(defval = size.small, title = "", options = [size.auto, size.tiny, size.small, size.normal, size.large, size.huge], inline = "volume")
bool mergeConsecutiveZones = input.bool(defval = true, title = "Merge Consecutive Zones", tooltip = "When enabled, volumes from consecutive liquidity zones are summed into a single total, and only the most recent label is displayed (previous labels in the sequence are removed).")
int showLast = input.int(defval = 500, title = "Show Last", minval = 10, step = 10, tooltip = "Number of bars back the indicator can plot.")
string timeframe = input.timeframe(defval = "", title = "Timeframe")
//#endregion

//#region ----- VARIABLES
bool highVol = false
bool liquidityZone = false
float vol = na
bool ltfLowVolatilityTrigger = false
//#endregion

//#region ----- CALCULATIONS
showLast := math.round(showLast * (timeframe.in_seconds(timeframe.period) / timeframe.in_seconds(timeframe)))

float htfVol = request.security(syminfo.tickerid, timeframe, volume, calc_bars_count = math.max(1, showLast))
float htfAvgVol = request.security(syminfo.tickerid, timeframe, ta.sma(volume, volLength), calc_bars_count = math.max(1, showLast))

array<float> ltfVol = request.security_lower_tf(syminfo.tickerid, timeframe, volume, ignore_invalid_timeframe = true, calc_bars_count = math.max(1, showLast))
array<float> ltfAvgVol = request.security_lower_tf(syminfo.tickerid, timeframe, ta.sma(volume, volLength), ignore_invalid_timeframe = true, calc_bars_count = math.max(1, showLast))

float htfAvgVolatility = request.security(syminfo.tickerid, timeframe, ta.stdev(close, volatilityLength), calc_bars_count = math.max(1, showLast))
bool htfLowVolatility = request.security(syminfo.tickerid, timeframe, ta.stdev(close, 5), calc_bars_count = math.max(1, showLast)) < htfAvgVolatility * 0.5

array<float> ltfAvgVolatility = request.security_lower_tf(syminfo.tickerid, timeframe, ta.stdev(close, volatilityLength), ignore_invalid_timeframe = true, calc_bars_count = math.max(1, showLast))
array<float> ltfLowVolatility = request.security_lower_tf(syminfo.tickerid, timeframe, ta.stdev(close, 5), ignore_invalid_timeframe = true, calc_bars_count = math.max(1, showLast))
if not na(ltfAvgVolatility) and ltfAvgVolatility.size() > 0 and not na(ltfLowVolatility) and ltfLowVolatility.size() > 0
    ltfLowVolatilityTrigger := ltfLowVolatility.last() < ltfAvgVolatility.last() * 0.5

if timeframe.in_seconds(timeframe) >= timeframe.in_seconds(timeframe.period)
    highVol := htfVol > htfAvgVol * volMultiplier
    liquidityZone := highVol and htfLowVolatility and barstate.isconfirmed
    vol := volumeMeasurement == "Currency Value" ? htfVol * close : htfVol
else if timeframe.in_seconds(timeframe) < timeframe.in_seconds(timeframe.period) and ltfVol.size() > 0 and ltfAvgVol.size() > 0
    highVol := ltfVol.last() > ltfAvgVol.last() * volMultiplier
    liquidityZone := highVol and ltfLowVolatilityTrigger and barstate.isconfirmed
    vol := volumeMeasurement == "Currency Value" ? ltfVol.last() * close : ltfVol.last()

int consecutiveZones = ta.barssince(not liquidityZone)
vol := math.sum(vol, mergeConsecutiveZones and liquidityZone ? consecutiveZones : 1)
//#endregion

//#region ----- PLOTTING
bgcolor(liquidityZone ? liquidityZonesColor : na, title = "Liquidity Zones")

if liquidityZone and plotZoneVolume
    label labels = label.new(bar_index, CndlA.isBullish() or CndlA.isBE() ? low : high, str.tostring(vol, format.volume), yloc = CndlA.isBullish() or CndlA.isBE() ? yloc.belowbar : yloc.abovebar, color = na, textcolor = CndlA.isBullish() or CndlA.isBE() ? #089981 : #ff5252, size = volumeLabelSize)
    if mergeConsecutiveZones and consecutiveZones > 1
        for i = 1 to consecutiveZones - 1
            label.delete(labels[consecutiveZones - i])
//#endregion

//#region ----- ALERTS
alertcondition(liquidityZone, "Liquidity Zone", "High-volume and low-volatility zone detected!")
//#endregion