LC Signal Generator

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © goodgains

//@version=5
indicator('LC_SignalGenerator', format=format.price, precision=2, overlay=false)

// @keywords: lc-signalgenerator, signal-generator, percent-change, request-security, multi-symbol, european-indices, market-breadth, es-futures, vix, score-threshold, session-scan, time-based-alerts, alerts, plot-circles, bgcolor, bullish-signal, bearish-signal, debug-mode, groups-score, daily-close

//INPUTS
debug_mode = input.bool(false, title = 'Debug Mode', group = 'Other Settings')
time_to_scan = input.session('1220-1221', title = 'Time For Scan', group = 'Other Settings', tooltip = 'Uses EST or NY Market Hours for timezone.')

g1_score = input.int(4, title = 'Score', group = 'Group 1')
g1_symbol1 = input.symbol("N100", title = 'Symbol 1', group = 'Group 1')
g1_symbol2 = input.symbol("STOXX50", title = 'Symbol 2', group = 'Group 1')
g1_symbol3 = input.symbol("FTSE100", title = 'Symbol 3', group = 'Group 1')
g1_symbol4 = input.symbol("CAC40", title = 'Symbol 4', group = 'Group 1')
g1_symbol5 = input.symbol("SSMI", title = 'Symbol 5', group = 'Group 1')
g1_symbol6 = input.symbol("IBEX35", title = 'Symbol 6', group = 'Group 1')
g1_symbol7 = input.symbol("DAX", title = 'Symbol 7', group = 'Group 1')

g2_symbol1 = input.symbol("ES1!", title = 'Symbol 1', group = 'Group 2')

g3_symbol1 = input.symbol("VIX", title = 'Symbol 1', group = 'Group 3')

//FUNCTION
f_pctchg(symbol) =>

    previous_close = request.security(symbol, 'D', close[1], barmerge.gaps_off, barmerge.lookahead_on)
    current_price = request.security(symbol, '', close)
    pct_change = math.round(((current_price - previous_close) / previous_close * 100), 100)
    pct_change


//GROUP 1 CALCS
g1_s1_value = f_pctchg(g1_symbol1) > 0 ? 1 : 0
g1_s2_value = f_pctchg(g1_symbol2) > 0 ? 1 : 0
g1_s3_value = f_pctchg(g1_symbol3) > 0 ? 1 : 0
g1_s4_value = f_pctchg(g1_symbol4) > 0 ? 1 : 0
g1_s5_value = f_pctchg(g1_symbol5) > 0 ? 1 : 0
g1_s6_value = f_pctchg(g1_symbol6) > 0 ? 1 : 0
g1_s7_value = f_pctchg(g1_symbol7) > 0 ? 1 : 0

g1_cond = (g1_s1_value + g1_s2_value + g1_s3_value + g1_s4_value + g1_s5_value + g1_s6_value + g1_s7_value) >= g1_score ? 1 : 0 

//GROUP 2 CALCS
g2_s1_value = f_pctchg(g2_symbol1)
g2_cond = g2_s1_value > 0 ? 1 : 0

//GROUP 3 CALCS
g3_s1_value = f_pctchg(g3_symbol1)
g3_cond = g3_s1_value < 0 ? 1 : 0


// PLOT DEBUG
// groups_cond = ( (g1_cond + g2_cond + g3_cond) == 3 ) ? 1 : -1
groups_score = g1_cond + g2_cond + g3_cond
alert_signal = groups_score == 3 ? 1 : groups_score == 0 ? -1 : 0 

plot(alert_signal, title = 'Groups Value', color = color.red, style = plot.style_circles)
plot( (g1_cond), title = 'DEBUG Group 1', style = plot.style_circles) // All GROUP 1
plot( (g2_cond), title = 'DEBUG Group 2', style = plot.style_circles) // All GROUP 2
plot( (g3_cond), title = 'DEBUG Group 3', style = plot.style_circles) // All GROUP 3

//SCAN - ALERTS
is_time_to_scan = time(timeframe.period, str.format('{0}:1234567', time_to_scan), 'America/New_York')


scan_cond = ( alert_signal == 1 or alert_signal == -1 ) and ( ( debug_mode ) or ( is_time_to_scan ) )
bgcolor(scan_cond and alert_signal == 1 ? color.lime : scan_cond and alert_signal == -1 ? color.red : na)


//TIME BASED ALERT
if is_time_to_scan
    if alert_signal == 1
        alert("signal:1", alert.freq_once_per_bar_close)
    else if alert_signal == -1
        alert("signal:-1", alert.freq_once_per_bar_close)
    else
        alert("signal:0", alert.freq_once_per_bar_close)
        
else if debug_mode == true
    if alert_signal == 1
        alert("signal:1", alert.freq_once_per_bar_close)
    else if alert_signal == -1
        alert("signal:-1", alert.freq_once_per_bar_close)
    else
        alert("signal:0", alert.freq_once_per_bar_close)