Laguerre RSI: Free TradingView Indicator (Pine Script)

Add It to Your TradingView Chart

1Copy the scriptPress Copy script above, or the copy button on the code below.
2Open the Pine EditorOpen a TradingView chart and choose Pine Editor at the bottom of the screen.
3Paste over the templateCreate a new indicator, select all of the template text and paste. Press Save and give it a name.
4Add it to the chartPress Add to chart, then adjust the settings with the gear icon next to its name.

Source Code

146 lines of Pine Script v6 from Laguerre RSI.txt, published under MPL-2.0 (file header). Keep the author's credit and licence lines when you reuse it.

Laguerre RSI.txt

//@version=6
indicator("Laguerre RSI", overlay=false)

enum LRSI_Type
    LaguerreRSI
    LaguerreRSI_FractalEnergy

lrsiType = input.enum(LRSI_Type.LaguerreRSI_FractalEnergy, "LaguerreRSI Type")


realPrice = ticker.new(prefix=syminfo.prefix, ticker=syminfo.ticker)
[realOpen, realHigh, realLow, realClose] = request.security(realPrice, timeframe.period, [open, high, low, close])


////////////////////////////////////////////////////////////////////////////////
// Oscillator Regions
////////////////////////////////////////////////////////////////////////////////

plot100 = plot(100, display=display.none, editable=false)
plot80 = plot(80, display=display.none, editable=false)
plot20 = plot(20, display=display.none, editable=false)
plot0 = plot(0, display=display.none, editable=false)
fill(plot100, plot80, color.rgb(178,40,51,40), "Overbought Region")
fill(plot0, plot20, color.rgb(56,142,60,40), "Oversold Region")


////////////////////////////////////////////////////////////////////////////////
// Laguerre RSI
////////////////////////////////////////////////////////////////////////////////

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// Developer: John EHLERS
// © KivancOzbilgic
// Author:Kıvanç Özbilgiç
lrsi_alpha = input.float(title='Alpha', minval=0, maxval=1, step=0.1, defval=0.2, group="Laguerre RSI")

lrsi_gamma = 1 - lrsi_alpha
lrsi_L0 = 0.0
lrsi_L0 := (1 - lrsi_gamma) * realClose + lrsi_gamma * nz(lrsi_L0[1])
lrsi_L1 = 0.0
lrsi_L1 := -lrsi_gamma * lrsi_L0 + nz(lrsi_L0[1]) + lrsi_gamma * nz(lrsi_L1[1])
lrsi_L2 = 0.0
lrsi_L2 := -lrsi_gamma * lrsi_L1 + nz(lrsi_L1[1]) + lrsi_gamma * nz(lrsi_L2[1])
lrsi_L3 = 0.0
lrsi_L3 := -lrsi_gamma * lrsi_L2 + nz(lrsi_L2[1]) + lrsi_gamma * nz(lrsi_L3[1])
lrsi_cu = (lrsi_L0 > lrsi_L1 ? lrsi_L0 - lrsi_L1 : 0) + (lrsi_L1 > lrsi_L2 ? lrsi_L1 - lrsi_L2 : 0) + (lrsi_L2 > lrsi_L3 ? lrsi_L2 - lrsi_L3 : 0)
lrsi_cd = (lrsi_L0 < lrsi_L1 ? lrsi_L1 - lrsi_L0 : 0) + (lrsi_L1 < lrsi_L2 ? lrsi_L2 - lrsi_L1 : 0) + (lrsi_L2 < lrsi_L3 ? lrsi_L3 - lrsi_L2 : 0)
lrsi_temp = lrsi_cu + lrsi_cd == 0 ? -1 : lrsi_cu + lrsi_cd
lrsi_LaRSI = 100 * (lrsi_temp == -1 ? 0 : lrsi_cu / lrsi_temp)


////////////////////////////////////////////////////////////////////////////////
// Laguerre RSI with Fractal Energy
// https://usethinkscript.com/threads/rsi-laguerre-with-fractal-energy-for-thinkorswim.116/
////////////////////////////////////////////////////////////////////////////////

nFE = input.int(title="NFE", tooltip="Number of bars used in Fractal Efficiency calculations", minval=1, defval=8, group="Laguerre RSI with Fractal Energy")
Glength = input.int(title="GLength", tooltip="Period length for Go/Gh/Gl/Gc filter", minval=1, defval=13, group="Laguerre RSI with Fractal Energy")
betaDev = input.int(title="BetaDev", tooltip="Controls reactivity in alpha/beta computations", minval=1, defval=8, group="Laguerre RSI with Fractal Energy")

float w = (2.0 * math.pi / Glength)
float beta = (1 - math.cos(w)) / (math.pow(1.414, 2.0 / betaDev) - 1)
float alpha = (-beta + math.sqrt(beta * beta + 2 * beta))
float Go = na
float Gh = na
float Gl = na
float Gc = na
Go := math.pow(alpha, 4) * realOpen + 4 * (1.0 - alpha) * nz(Go[1]) - 6 * math.pow( 1 - alpha, 2) * nz(Go[2]) + 4 * math.pow( 1 - alpha, 3) * nz(Go[3]) - math.pow( 1 - alpha, 4 ) * nz(Go[4])
Gh := math.pow(alpha, 4) * realHigh + 4 * (1.0 - alpha) * nz(Gh[1]) - 6 * math.pow( 1 - alpha, 2 ) * nz(Gh[2]) + 4 * math.pow( 1 - alpha, 3 ) * nz(Gh[3]) - math.pow( 1 - alpha, 4 ) * nz(Gh[4])
Gl := math.pow(alpha, 4) * realLow + 4 * (1.0 - alpha) * nz(Gl[1]) - 6 * math.pow( 1 - alpha, 2 ) * nz(Gl[2]) + 4 * math.pow( 1 - alpha, 3 ) * nz(Gl[3]) - math.pow( 1 - alpha, 4 ) * nz(Gl[4])
Gc := math.pow(alpha, 4) * realClose + 4 * (1.0 - alpha) * nz(Gc[1]) - 6 * math.pow( 1 - alpha, 2 ) * nz(Gc[2]) + 4 * math.pow( 1 - alpha, 3 ) * nz(Gc[3]) - math.pow( 1 - alpha, 4 ) * nz(Gc[4])
// Variables:
float o = na
float h = na
float l = na
float c = na
float CU1 = na
float CU2 = na
float CU = na
float CD1 = na
float CD2 = na
float CD = na
float L0 = na
float L1 = na
float L2 = na
float L3 = na

// Calculations
o := (Go + nz(Gc[1])) / 2.0
h := math.max(Gh, nz(Gc[1]))
l := math.min(Gl, nz(Gc[1]))
c := (o + h + l + Gc) / 4.0
gamma = math.log(math.sum((math.max(Gh, nz(Gc[1])) - math.min(Gl, nz(Gc[1]))), nFE) / (ta.highest(Gh, nFE) - ta.lowest(Gl, nFE))) / math.log(nFE)
L0 := (1.0 - gamma) * Gc + gamma * nz(L0[1])
L1 := -gamma * L0 + nz(L0[1]) + gamma * nz(L1[1])
L2 := -gamma * L1 + nz(L1[1]) + gamma * nz(L2[1])
L3 := -gamma * L2 + nz(L2[1]) + gamma * nz(L3[1])
if L0 >= L1
    CU1 := L0 - L1
    CD1 := 0
else
    CD1 := L1 - L0
    CU1 := 0

if L1 >= L2
    CU2 := CU1 + L1 - L2
    CD2 := CD1
else
    CD2 := CD1 + L2 - L1
    CU2 := CU1

if L2 >= L3
    CU := CU2 + L2 - L3
    CD := CD2
else
    CU := CU2
    CD := CD2 + L3 - L2

lrsife_LaRSI = (CU + CD != 0) ? 100 * (CU / (CU + CD)) : 0


////////////////////////////////////////////////////////////////////////////////
// Laguerre RSI Plotting
////////////////////////////////////////////////////////////////////////////////

LaRSI = (lrsiType == LRSI_Type.LaguerreRSI_FractalEnergy) ? lrsife_LaRSI : lrsi_LaRSI
plot(LaRSI, title='Laguerre RSI', linewidth=2, color=color.white)


////////////////////////////////////////////////////////////////////////////////
// Alerts
////////////////////////////////////////////////////////////////////////////////

// Enter long - LRSI
enterLongLRSI = ta.crossover(LaRSI, 20)
plotshape(enterLongLRSI, title="Enter LONG - LRSI", style=shape.arrowup, location=location.belowbar, color=color.green, size=size.normal, force_overlay=true, display=display.pane)
alertcondition(enterLongLRSI, title='Enter LONG - LRSI', message='Laguerre RSI crossed OVER 20')


// Enter short - LRSI
enterShortLRSI = ta.crossunder(LaRSI, 80)
plotshape(enterShortLRSI, title="Enter SHORT - LRSI", style=shape.arrowdown, location=location.abovebar, color=color.red, size=size.normal, force_overlay=true, display=display.pane)
alertcondition(enterShortLRSI, title='Enter SHORT - LRSI', message='Laguerre RSI crossed UNDER 80')


bgcolor(enterLongLRSI ? color.new(color.green, 50) : enterShortLRSI ? color.new(color.red, 50) : na, title="LRSI Entry Signal Background")

Overview

Laguerre RSI offers a classic four-stage Laguerre filter on close, controlled by alpha, and an alternate mode that builds alpha from fractal-energy style filters on open, high, low, and close. Shaded fills mark overbought and oversold zones. The type input switches modes; alpha, NFE, GLength, and BetaDev change smoothing and reactivity. The excerpt shows no trade signals or exit rules.

Classic Laguerre RSI filter
Fractal energy calculation mode
Overbought and oversold region fills
Adjustable alpha and filter lengths

Details

Published by

lunarticktrading on GitHub

Code credit

KivancOzbilgic, as written in the script's header

Type

Indicator, Pine Script v6

Draws

Separate pane below the chart

Markets

Any symbol

Timeframes

Any timeframe

Risk Notes

No repainting, lookahead or stacked entries were found in its code or README. That says nothing about how well it works: test it first.

File

Laguerre RSI.txt

Repository

github.com/lunarticktrading/TradingView. See its other scripts in the library

Settings

The inputs you can change from the gear icon on the chart. Defaults are the author's.

Setting	Type	Default	Variable
LaguerreRSI Type	`enum`	`LRSI_Type.LaguerreRSI_FractalEnergy`	`lrsiType`
Alpha	`float`	`0.2`	`lrsi_alpha`
NFE	`int`	`8`	`nFE`
GLength	`int`	`13`	`Glength`
BetaDev	`int`	`8`	`betaDev`

Third-party code. ForexR did not write, test or endorse this script, and the summary above was generated automatically from its code and README. Indicators describe the past, and a strategy's backtest can look better than live trading, especially when a script repaints. Check it in the Strategy Tester and on a demo account before you rely on it.

Similar Pine Scripts

Asymmetrical RSI

by everget

948

Asymmetrical RSI is an indicator that computes a custom relative strength index from the rate of change of a user-selected source. It plots the resulting ARSI line in a separate pane with color coding that turns green above the overbought level and red below t

Indicator v4 Oscillators & momentum

Updated 10 days ago · GPL-3.0

Momentum Setup - RSI Directional Momentum Indicator

by ArunKBhaskar

575

This indicator calculates momentum setups based on the Relative Strength Index (RSI) and plots in a separate pane. It offers multiple scanning modes such as Continuous Break, Continuous Retracement, Flip Break, Flip Retracement, and both regular and hidden div

Indicator v6 Oscillators & momentumDivergence Repaints

Updated 1 year ago · MPL-2.0

Beep Boop

by magic8bot

409

This indicator calculates a modified MACD oscillator and signal line alongside a trend EMA filter, plotting the output as a stylized column histogram in a separate pane. Instead of plotting true MACD distance, it quantifies positive and negative histogram mome

Indicator v4 Oscillators & momentumTrend

Updated 3 years ago · MIT

Directional Movement Index [Alorse]

by Alorse

330

This indicator plots the Average Directional Index in a separate pane and colors the line teal or maroon according to whether plus DI is above minus DI. A horizontal key level and a silver background mark periods when ADX exceeds that threshold. With labels en

Indicator v4 TrendOscillators & momentum

Updated 2 months ago · None stated

Example: Graph Style - 4th Dimension RSI

by ricardosantos79

261

This indicator demonstrates an experimental graph-style scatter visualization within a separate pane using Pine Script arrays. It tracks two features across recent bars: the single-bar price change and a scaled 14-period Relative Strength Index. Values are loa

Indicator v4 Oscillators & momentum

Updated 4 years ago · None stated

KD指標

by TaichiS

219

This script calculates and plots a Stochastic Oscillator (KD indicator) in a separate chart pane. It determines the fast stochastic value over a 9-period lookback, then applies a 3-period Simple Moving Average (SMA) to create the %K line, and a second 3-period

Indicator v4 Oscillators & momentum

Updated 5 years ago · None stated

More indicators

Laguerre RSI

Add It to Your TradingView Chart

Source Code

Overview

Details

Published by

Code credit

Type

Draws

Category

Markets

Timeframes

Risk Notes

File

Repository

Settings

Similar Pine Scripts

Asymmetrical RSI

Momentum Setup - RSI Directional Momentum Indicator

Beep Boop

Directional Movement Index [Alorse]

Example: Graph Style - 4th Dimension RSI

KD指標

Trade Your Charts With a Regulated Broker