Intraday Spark Chart [AstrideUnicorn]

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © AstrideUnicorn

//@version=6
indicator("Intraday Spark Chart [AstrideUnicorn]", "ISC", overlay=false, scale=scale.right, max_lines_count=500, max_labels_count=500)

// Input for asset selection. This allows user to display other asset intraday price action to perform intermarket analysis.
targetSymbol = input.symbol("", "Asset", tooltip="Leave empty for current symbol.", group = "Main")

// Visual settings for controlling colors and transparencies of the indicator elements.

outlineTransparency = input.int(0, title="Plot Transp.", minval=0, maxval=100, step=1, group = "Visual", tooltip="Main plot transparency: 0 - non transparent, 100 - fully transparent.")
areaTransparency = input.int(80, title="Fill Transp.", minval=0, maxval=100, step=1, group = "Visual", tooltip="Area fill transparency: 0 - non transparent, 100 - fully transparent.")
positiveColor = input.color(#4CAF50, title = "Positive", group = "Visual", tooltip="Color when price is above the daily open")
negativeColor = input.color(#F44336, title = "Negtative", group = "Visual", tooltip="Color when price is below the daily open")
neutralColor = input.color(#787B86, title = "Neutral", group = "Visual", tooltip="Color for the static elements and information.")

// Timeframe check. If timeframe is higher than 4 hours display a warning instead of the indicator.
var table tfWarning = table.new(position.middle_center, 1, 1)
isIntraday = timeframe.in_seconds() <= 4 * 60 * 60
showWarning = not isIntraday
if showWarning
    table.cell(tfWarning, 0, 0, "This is an intraday indicator. Please, switch to a lower timeframe.", text_color=neutralColor)

// Get pricing data for selected asset.
assetClose = request.security(targetSymbol == "" ? syminfo.tickerid : targetSymbol, 
  timeframe.period, close, lookahead=barmerge.lookahead_off)

dailyOpen = isIntraday ? request.security(targetSymbol == "" ? syminfo.tickerid : targetSymbol, "D", open,
  lookahead=barmerge.lookahead_on) : na
// lookahead_on is needed to align daily open prices with the corresponding intraday timeframe pricing data. 

// Calculate percentage changes using selected asset's data
percentChange = isIntraday ? (assetClose - dailyOpen) / dailyOpen * 100 : na

// Day identification
isNewDay = isIntraday ? ta.change(time("D")) : 0


// Calculate the average daily range as a percentage of the daily opening price 
// to adjust the indicator's plotting area and to position the elements on it.
dailyATR = request.security(targetSymbol, "1D", ta.sma(100*(high-low)/open,500))

// Vertical lines for day separators
if isIntraday and isNewDay != 0
    line.new(bar_index, -1.1*dailyATR, bar_index, 1.1*dailyATR, color=neutralColor, width=1, style=line.style_dotted, xloc=xloc.bar_index)

// Baseline
plot(isIntraday ? 0 : na, "Zero Line", color= neutralColor, linestyle = plot.linestyle_dotted)

// Main plots
outlineColor = not isIntraday ? color.new(color.white, 100) : 
           isNewDay !=0 ? color.new(color.black, 100) : 
           percentChange > 0 ? color.new(positiveColor, outlineTransparency) : 
           color.new(negativeColor, outlineTransparency)

areaColor = not isIntraday ? color.new(color.white, 100) : 
           isNewDay !=0 ? color.new(color.black, 100) : 
           percentChange > 0 ? color.new(positiveColor, areaTransparency) : 
           color.new(negativeColor, areaTransparency)

plot(percentChange, "Plot", color=outlineColor, linewidth=2, style=plot.style_line)
plot(percentChange, "Fill", color=areaColor, linewidth=1, style=plot.style_area)

// Daily open price label
if isIntraday and isNewDay !=0
    label.new(
      bar_index, dailyATR, 
      text="Op:"+str.tostring(dailyOpen, format.mintick), 
      color=color.new(color.gray, 100), 
      textcolor=color.new(neutralColor,0), 
      style=label.style_label_left, 
      size=size.small, 
      yloc=yloc.price
     )

// Daily percentage change label system
var label[] dayLabels = array.new_label(0)
var int currentDayLabelIndex = -1

if isIntraday

    isPositive = percentChange >= 0
    if isNewDay !=0
        if array.size(dayLabels) > 0 and currentDayLabelIndex >= 0
            prevDayPct = percentChange[1]
            prevIsPositive = prevDayPct >= 0
            str_arrow = prevIsPositive ? "▲" : "▼"
            label.set_text(array.get(dayLabels, currentDayLabelIndex),str_arrow + str.format("{0, number, +#.##%;-#.##%}", prevDayPct/100))
            label.set_textcolor(array.get(dayLabels, currentDayLabelIndex), prevIsPositive ? color.new(positiveColor,0) : color.new(negativeColor,0))
            label.set_color(array.get(dayLabels, currentDayLabelIndex), prevIsPositive ? color.new(positiveColor,100) : color.new(negativeColor,100))
        
        
        lbl = label.new(bar_index, 0.75*dailyATR, text = str.format("{0, number, +#.##%;-#.##%}", percentChange/100), 
          color=color.new(isPositive ? positiveColor : negativeColor, 100), 
          textcolor=isPositive ? color.new(positiveColor,0) : color.new(negativeColor,0), style=label.style_label_left, size=size.small, yloc=yloc.price)
        array.push(dayLabels, lbl)
        currentDayLabelIndex := array.size(dayLabels) - 1
    

    if barstate.islast and array.size(dayLabels) > 0 and currentDayLabelIndex >= 0
        str_arrow_current = isPositive ? "▲" : "▼"
        label.set_text(array.get(dayLabels, currentDayLabelIndex), str_arrow_current + str.format("{0, number, +#.##%;-#.##%}", percentChange/100))
        label.set_textcolor(array.get(dayLabels, currentDayLabelIndex), isPositive ? color.new(positiveColor,0) : color.new(negativeColor,0))


// Create and manage the ticker indication table
var table tickerTable = table.new(position = position.bottom_right, columns = 1, rows = 1, border_width = 1)

// Update the ticker table on the Last bar
if barstate.islast and targetSymbol !=  ticker.standard(syminfo.tickerid) and isIntraday
    table.cell(tickerTable, column = 0, row = 0, text = str.tostring(targetSymbol), text_color = isIntraday and targetSymbol==""? color.new(color.black, 100) : color.new(neutralColor,0), text_size = size.normal)