Intrabar Profile [Kioseff Trading]

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © KioseffTrading

//@version=6
indicator("Intrabar Profile [Kioseff Trading]", overlay = true, max_boxes_count = 500, max_labels_count = 500, max_lines_count = 500, max_polylines_count = 100, calc_bars_count = 500)


enum granularity

    m5 = "5-Minute"
    m1 = "1-Minute"
    s1 = "1-Second"
    t1 = "1-Tick"

profType            = input.string(defval = "VP", title = "Profile Type", options = ["VP", "Delta"])
gran                = input.enum(defval = granularity.m1, title = "Granularity", options = [granularity.m5, granularity.m1, granularity.s1, granularity.t1])
upColAdv2           = input.color(defval = #96d3c8, title = "Buy-Side Color", inline = "ADV UP", group = "Focus Mode"), upColAdv = input.color(defval = #00ffff, title = "", inline = "ADV UP", group = "Focus Mode")
dnColAdv2           = input.color(defval = #d39696, title = "Sell-Side Color", inline = "ADV DN", group = "Focus Mode"), dnColAdv = input.color(defval = #8f1b1b, title = "", inline = "ADV DN", group = "Focus Mode")
advCol              = input.color(defval = color.white, title = "Text Color", group = "Focus Mode")
rows                = input.int(defval = 11, minval = 5, maxval = 200, title = "Profile Rows")

showVolAtLevel     = input.bool(defval = false, title = "Show Volume At Level", group = "Mini Profile Main Settings")
miniProfTransp     = input.int(0, minval = 0, maxval = 100, title = "Mini Profile Transparency", group = "All Profile Settings")
showVA          = input.bool(defval = true, title = "Show VA", group = "VA")
customPOCcol    = input.bool(defval = true, title = "", inline = "POC")
pocCol          = input.color(defval = #e5ff55, title = "POC Color", inline = "POC")

var tf = switch gran

    granularity.m1  => "1"
    granularity.s1  => "1S"
    granularity.t1  => "1T"


direction() =>

    if gran == granularity.t1

        switch

            close == bid => -1
            close == ask =>  1
            => math.sign(close - close[1])

    else

        math.sign(close - close[1])

everyBarVP() =>

    [h, l, vol] = request.security_lower_tf("", tf, [high, low, volume * direction()])

    if vol.size() > 0

        Range = (high - low) / (rows - 1)

        levelsArr  = array.new<float>(rows, 0)
        vpArr      = array.new<float>(rows, 0)
        deltaArr   = array.new<float>(rows, 0)

        for i = 0 to rows - 1

            levelsArr.set(i, low + (Range * i))

        for [i, data] in vol

            bot = levelsArr.binary_search_leftmost(l.get(i))
            top = levelsArr.binary_search_leftmost(h.get(i))

            div    = data / (math.abs(top - bot) + 1)
            absDiv = math.abs(div)

            for x = bot to top

                vpArr   .set(x, vpArr.get(x) + absDiv)
                deltaArr.set(x, deltaArr.get(x) + div)

        poc   = vpArr.indexof(vpArr.max()),
        indUp = poc, indDn = poc, sum = 0., size = vpArr.size()
        total = vpArr.sum() * .7

        for i = 0 to size - 1

            if indUp == indDn

                sum += vpArr.get(indUp)

                if sum >= total
                    break

                indUp += 1
                indDn -= 1
                continue

            if indUp < size

                sum += vpArr.get(indUp)

                if sum >= total
                    break

                indUp += 1

            if indDn > -1

                sum += vpArr.get(indDn)

                if sum >= total
                    break

                indDn -= 1


        if vpArr.sum() != 0

            minVol = vpArr.min(), rangeVol = vpArr.range()

            absDeltaArr = deltaArr   .abs()
            minDelta    = absDeltaArr.min()
            rangeDelta  = absDeltaArr.range()

            for [i, data] in vpArr

                norm = int(na), getDelta = deltaArr.get(i), absDelta = absDeltaArr.get(i)

                if profType == "VP"

                    norm := math.round(1 + ((data - minVol) * 10) / rangeVol)

                else

                    norm := math.round(1 + ((absDelta - minDelta) * 10) / rangeDelta)

                    if math.sign(getDelta) == -1

                        norm *= -1

                level = levelsArr.get(i)
                getText = "█"

                signNorm = math.sign(norm)

                if signNorm == 1 or profType == "VP"

                    if norm > 1
                        for x = 0 to math.min(norm - 1, 9)
                            getText += "█"

                    if str.length(getText) < 10

                        for x = str.length(getText) to 10
                            getText += " "

                    else if str.length(getText) == 10

                        getText += " "

                else

                    getText := ""

                    width  = 11
                    blocks = math.min(math.abs(norm), width)
                    spaces = width - blocks

                    if spaces > 0
                        for x = 0 to spaces - 1
                            getText += " "

                    if blocks > 0
                        for x = 0 to blocks - 1
                            getText += "█"


                volAtLevel = str.tostring(getDelta, format.volume)

                if showVolAtLevel

                    getText := volAtLevel + getText

                col = switch math.sign(close - open)

                    1  => color.new(color.from_gradient(norm, 0, 10, upColAdv, upColAdv2), miniProfTransp)
                    -1 => color.new(color.from_gradient(norm, 0, 10, dnColAdv, dnColAdv2), miniProfTransp)

                if showVolAtLevel

                    if profType == "VP" or signNorm == 1

                        getText += switch

                            profType == "VP" => str.tostring(data, format.volume)
                            => str.tostring(getDelta, format.volume)

                if showVA

                    if i <= indDn or i >= indUp

                        col := color.new(color.gray, miniProfTransp)

                if customPOCcol
                    if i == poc
                        col := pocCol

                if profType == "VP" or signNorm == 1

                    box.new(bar_index, level, bar_index + 1, level + Range, text = getText,
                                                            text_halign   = text.align_left,
                                                            text_valign   = text.align_center,
                                                            border_color  = color(na),
                                                            bgcolor       = #00000000,
                                                            text_color    = col,
                                                            force_overlay = true
                                                            )

                else

                    box.new(bar_index - 1, level, bar_index, level + Range, text = getText,
                                                            text_halign   = text.align_right,
                                                            text_valign   = text.align_center,
                                                            border_color  = color(na),
                                                            bgcolor       = #00000000,
                                                            text_color    = col,
                                                            force_overlay = true
                                                            )


everyBarVP()