Intrabar Efficiency Ratio

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © TradingView

//@version=6
indicator("Intrabar Efficiency Ratio", precision = 4)

// Intrabar Efficiency Ratio indicator
// v3, 2026.01.09

// This code's style is based on the recommendations from the Pine Script User Manual's Style guide:
//    https://www.tradingview.com/pine-script-docs/writing/style-guide/



import PineCoders/Time/5 as PCtime
import PineCoders/lower_tf/5 as PCltf



//#region ———————————————————— Constants and Inputs


// ————— Constants

// Colors
color  AQUA    = color.aqua
color  FUCHSIA = color.fuchsia
color  GRAY    = #80808080
color  GRAY_LT = #f5f3f3
color  LIME    = color.lime
color  MAROON  = color.maroon
color  ROYAL   = #3BB3E4
color  ROSE    = #FF0080
color  TEAL    = color.teal
color  WHITE   = color.white
color  YELLOW  = color.yellow

// MAs
string MA01 = "Simple"
string MA02 = "Exponential"
string MA03 = "Wilder (RMA)"
string MA04 = "Weighted"
string MA05 = "Volume-Weighted"
string MA06 = "Arnaud Legoux"
string MA07 = "Hull"

// LTF distinction
string LTF1  = "Covering most chart bars (least precise)"
string LTF2  = "Covering some chart bars (less precise)"
string LTF3  = "Covering less chart bars (more precise)"
string LTF4  = "Covering few chart bars (very precise)"
string LTF5  = "Covering the least chart bars (most precise)"
string LTF6  = "~12 intrabars per chart bar"
string LTF7  = "~24 intrabars per chart bar"
string LTF8  = "~50 intrabars per chart bar"
string LTF9  = "~100 intrabars per chart bar"
string LTF10 = "~250 intrabars per chart bar"

// Display types
string DT01 = "Line"
string DT02 = "Candles"
string DT03 = "Circles"

// Tooltips
string TT_DT = (
    "Three display options are available:"
    + "\n• 'Line' displays an IER-based moving average of the selected type using the medium length."
    + "\n• 'Candles' displays candles using the IER value and the short and long MAs."
    + "\n• 'Circles' displays circles to show the values of all three IER-based MAs."
)
string TT_LTF  = (
    "Controls the number of intrabars that the indicator analyzes per chart bar. "
    + "Increasing the intrabars per chart bar enables more precise calculations. However, it also reduces the number "
    + "of chart bars that the indicator can analyze. "
    + "The first five options determine the requested lower timeframe based on a desired relative amount of chart bar "
    + "coverage. The last five determine the timeframe based on an approximate number of intrabars per chart bar."
)
string TT_CDL = (
    "Specifies the colors for the 'Candle' display in the following order: "
    + "down body, down wick, up body, up wick."
)
string TT_CIR = (
    "Specifies the colors for the 'Circles' display in the following order: "
    + "extreme low, down color, up color, extreme high."
)
string TT_RW  = (
    "If selected, the indicator applies weighting to IER values based on the percentage rank of the close-to-close "
    + "price change over the specified number of bars."
)
string TT_LEN = (
    "The short, medium and long lengths for the moving averages. Different display modes use different "
    + "MAs. Only the 'Circles' display uses all three."
)

// ————— Inputs

string  GRP1 = "Visuals"
string  displayTypeInput        = input.string(DT01,     "Display",                  group = GRP1, inline = "10", options = [DT01, DT02, DT03], tooltip = TT_DT)
bool    isLine                  = displayTypeInput == DT01
bool    isCandles               = displayTypeInput == DT02
bool    isCircles               = displayTypeInput == DT03
color   lineColorInput          = input.color(AQUA,      "Line   ",                  group = GRP1, inline = "13", active =isLine)
color   bearBodyInput           = input.color(FUCHSIA,   "Candles",                  group = GRP1, inline = "11", active = isCandles, tooltip = TT_CDL)
color   bearWickInput           = input.color(MAROON,    "",                         group = GRP1, inline = "11", active = isCandles)
color   bullBodyInput           = input.color(LIME,      "",                         group = GRP1, inline = "11", active = isCandles)
color   bullWickInput           = input.color(TEAL,      "",                         group = GRP1, inline = "11", active = isCandles)
color   lowColorInput           = input.color(YELLOW,    "Circles ",                 group = GRP1, inline = "12", active = isCircles, tooltip = TT_CIR)
color   bearColorInput          = input.color(ROSE,      "",                         group = GRP1, inline = "12", active = isCircles)
color   bullColorInput          = input.color(ROYAL,     "",                         group = GRP1, inline = "12", active = isCircles)
color   highColorInput          = input.color(LIME,      "",                         group = GRP1, inline = "12", active = isCircles)
bool    showInfoBoxInput        = input.bool(true,       "Show information box ",    group = GRP1)
string  infoBoxSizeInput        = input.string("small",  "Size ",                    group = GRP1, inline = "14", active = showInfoBoxInput, options = ["tiny", "small", "normal", "large", "huge", "auto"])
string  infoBoxYPosInput        = input.string("bottom", "↕",                        group = GRP1, inline = "14", active = showInfoBoxInput, options = ["top", "middle", "bottom"])
string  infoBoxXPosInput        = input.string("right",  "↔",                        group = GRP1, inline = "14", active = showInfoBoxInput, options = ["left", "center", "right"])
color   infoBoxColorInput       = input.color(GRAY,      "",                         group = GRP1, inline = "14", active = showInfoBoxInput)
color   infoBoxTxtColorInput    = input.color(GRAY_LT,   "T",                        group = GRP1, inline = "14", active = showInfoBoxInput)

string  GRP2 = "Settings"
string  ltfModeInput            = input.string(LTF3,     "Intrabar precision",       group = GRP2, options = [LTF1, LTF2, LTF3, LTF4, LTF5, LTF6, LTF7, LTF8, LTF9, LTF10], tooltip = TT_LTF)
string  maTypeInput             = input.string(MA06,     "MA type ",                 group = GRP2, inline = "20", options = [MA01, MA02, MA03, MA04, MA05, MA06, MA07])
int     shortLengthInput        = input.int(10,          "MA lengths: S",            group = GRP2, inline = "21", active = isCandles or isCircles)
int     midLengthInput          = input.int(20,          "M",                        group = GRP2, inline = "21", active = isLine or isCircles)
int     longLengthInput         = input.int(40,          "L",                        group = GRP2, inline = "21", active = isCandles or isCircles, tooltip = TT_LEN)
bool    rankWeightInput         = input.bool(false,      "Weigh using relative close changes", group = GRP2, inline = "22")
int     rankLengthInput         = input.int(100,         "",                         group = GRP2, inline = "22", tooltip = TT_RW, active = rankWeightInput)
//#endregion



//#region ———————————————————— Functions


// @function        Calculates a moving average of a source series, with a specified type and length.
// @param source    (series float) The series of values to process.
// @param length    (simple int) The length value for the moving average.
// @param maType    (simple string) Specifies the type of moving average. Accepts the value of one of the `MA*`
//                  constants declared above.
// @returns         (float) The moving average of the `source` series.
ma(series float source, simple int length, simple string maType) =>
    float result = switch maType
        MA01 => ta.sma(source,  length)
        MA02 => ta.ema(source,  length)
        MA03 => ta.rma(source,  length)
        MA04 => ta.wma(source,  length)
        MA05 => ta.vwma(source, length)
        MA06 => ta.alma(source, length, 0.85, 6)
        MA07 => ta.hma(source,  length)
        => na


// @function        Selects an input color (`highColorInput`, `lowColorInput`, `bullColorInput`, or `bearColorInput`)
//                  based on the 100-bar percent rank of the specified value.
// @param value     (series float) The series of values for which to calculate the color.
// @returns         (color) The selected input color.
plotColor(series float value) =>
    float percent = ta.percentrank(value, 100)
    color result = switch
        percent > 90 => highColorInput
        percent < 10 => lowColorInput
        percent > 50 => bullColorInput
        =>              bearColorInput
//#endregion



//#region ———————————————————— Calculations


// @variable A string representing the lower timeframe for which to retrieve intrabar data.
var string ltfString = PCltf.ltf(ltfModeInput, LTF1, LTF2, LTF3, LTF4, LTF5, LTF6, LTF7, LTF8, LTF9, LTF10)

// Retrieve the absolute bar-to-bar change in the `close` value for each intrabar in the chart bar, and compute the sum.
array<float> travels = request.security_lower_tf(
    syminfo.tickerid, ltfString, math.abs(ta.change(close)), calc_bars_count = 200000
)
float totalTravels   = travels.sum()
// Calculate the one-bar change in the `close` value on the chart's timeframe.
float chartBarChange = nz(ta.change(close))

// Calculate a weight using the relative size of the one-bar price change.
float weight = rankWeightInput ? ta.percentrank(math.abs(chartBarChange), rankLengthInput) / 100.0 : 1.0

// Compute the IER and its MAs.
float ier     = nz(chartBarChange / totalTravels) * weight
float maLong  = ma(ier, longLengthInput,  maTypeInput)
float maMid   = ma(ier, midLengthInput,   maTypeInput)
float maShort = ma(ier, shortLengthInput, maTypeInput)

// Calculate candle data.
float o = maLong
float h = math.max(ier, maLong, maShort)
float l = math.min(ier, maLong, maShort)
float c = maShort
color candleColor = c > o ? bullBodyInput : bearBodyInput
color wickColor   = c > o ? bullWickInput : bearWickInput

// Retrieve intrabar and chart bar information for the table display.
[intrabars, chartBarsCovered, avgIntrabars] = PCltf.ltfStats(travels)
int chartBars = bar_index + 1
//#endregion



//#region ———————————————————— Visuals


// Declare variables to store display settings for the plots.
candlePlotDisplay = isCandles ? display.all  - display.pane : display.none
candleDisplay     = isCandles ? display.pane : display.none
circleDisplay     = isCircles ? display.all  : display.none
lineDisplay       = isLine    ? display.all  : display.none

// Plot the candle values.
plot(o, "IER candle open",  candleColor, display = candlePlotDisplay)
plot(h, "IER candle high",  wickColor,   display = candlePlotDisplay)
plot(l, "IER candle low",   wickColor,   display = candlePlotDisplay)
plot(c, "IER candle close", candleColor, display = candlePlotDisplay)
plotcandle(o, h, l, c, "IER candles", candleColor, wickColor, bordercolor = candleColor, display = candleDisplay)

// Plot the IER-based MAs.
plot(maLong,  "Long MA",  color.new(plotColor(maLong),  20), 2, plot.style_circles, display = circleDisplay)
plot(maMid,   "Mid MA",   color.new(plotColor(maMid),   10), 1, plot.style_circles, display = circleDisplay)
plot(maShort, "Short MA", color.new(plotColor(maShort),  0), 1, plot.style_circles, display = circleDisplay)
plot(maMid,   "Mid MA",   lineColorInput,                    1, plot.style_line,    display = lineDisplay)
hline(0)

// Plot key information in the status line and the Data Window.
displayLocations = display.status_line + display.data_window
plot(ier,               "Intrabar Efficiency Ratio", display = displayLocations)
plot(intrabars,         "Intrabars in chart bar",    display = displayLocations)
plot(avgIntrabars,      "Avg. intrabars",            display = displayLocations)
plot(chartBarsCovered,  "Chart bars covered",        display = displayLocations)
plot(chartBars,         "Total chart bars",          display = displayLocations)
plot(totalTravels,      "totalTravels",              display = displayLocations)
plot(chartBarChange,    "chartBarChange",            display = displayLocations)
plot(weight,            "weight",                    display = displayLocations)

// Logic for the information box display
if showInfoBoxInput
    var table infoBox = table.new(infoBoxYPosInput + "_" + infoBoxXPosInput, 1, 1)
    string formattedLtf = PCtime.formattedNoOfPeriods(timeframe.in_seconds(ltfString) * 1000)
    string txt = str.format(
        "Intrabar timeframe: {0}\nAvg intrabars per chart bar: {1,number,#.#}\nChart bars covered: {2} of {3}",
        formattedLtf, avgIntrabars, chartBarsCovered, chartBars
    )
    if barstate.isfirst
        table.cell(
            infoBox, 0, 0, txt, text_color = infoBoxTxtColorInput, text_size = infoBoxSizeInput,
            bgcolor = infoBoxColorInput
        )
    else if barstate.islast
        table.cell_set_text(infoBox, 0, 0, txt)

// Runtime errors
if ta.cum(intrabars) == 0 and barstate.islast
    runtime.error(str.format("No intrabar information available for the ''{0}'' timeframe.", ltfString))
else if shortLengthInput > midLengthInput
    runtime.error("The length of the short MA must be less than or equal to that of the medium MA.")
else if midLengthInput > longLengthInput
    runtime.error("The length of the medium MA must be less than or equal to that of the long MA.")
//#endregion