Impulse-Orders

// © GoldRat
//@version=5
strategy("[Order] Impulse-Orders", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=1, pyramiding=100)

Fibo = input.float(0.5, "Fibo", minval=0.0, maxval=1.0, step=0.01)
Percent = input.float(2.0, "Percent", minval=0.0, maxval=100.0, step=0.01)

var bool Up = false
var bool Dn = false
var float StartUp = 0
var float EndUp = 0
var float StartDn = 0
var float EndDn = 0
int Signal = 0

// Crossed 50% fibo
if Up and low[1] <= StartUp + (EndUp - StartUp) * Fibo
    Up := false
if Dn and high[1] >= StartDn - (StartDn - EndDn) * Fibo
    Dn := false

// Impulse start
impulseUp_startCondition = not Up and close[1] > open[1] and close[2] > open[2] and low[1] > low[2] + ((high[2] - low[2]) * Fibo)

if impulseUp_startCondition
    // Up
    StartUp := low[2]
    EndUp := high[1] > high[2] ? high[1] : high[2]
    Up := true

plotshape(impulseUp_startCondition, style=shape.circle, color=color.green,  offset=-2)

impulseDown_startCondition = not Dn and close[1] < open[1] and close[2] < open[2] and high[1] < high[2] - ((high[2] - low[2]) * Fibo)

if impulseDown_startCondition
    // Down
    StartDn := high[2]
    EndDn := low[1] < low[2] ? low[1] : low[2]
    Dn := true

plotshape(impulseDown_startCondition, style=shape.circle, color=color.red, location=location.belowbar, offset=-2)

// Impulse end    
if Up and high[1] > EndUp    
    // Up
    EndUp := high[1]
if Dn and low[1] < EndDn    
    // Down
    EndDn := low[1]

// Signal
if barstate.isnew and Signal != 0
    Signal := 0
if Signal == 0 
    if Up and (EndUp - StartUp) >= StartUp * Percent / 100.0
        message = '"type":"long", "minPrice":"' + str.tostring(StartUp) + '","maxPrice":"' + str.tostring(high[1]) + '"'
        
        strategy.entry('Long Impulse', strategy.long, alert_message=message)
        Signal := 1
        Up := false
    if Dn and (StartDn - EndDn) >= StartDn * Percent / 100.0
        
        message = '"type":"short", "minPrice":"' + str.tostring(low[1]) + '","maxPrice":"' + str.tostring(StartDn) + '"'
        strategy.entry('Short Impulse', strategy.short, alert_message=message)
        Signal := -1
        Dn := false

plotarrow(Signal, maxheight=20)