HLevel

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// Author: Anton Stupenkov
// Email: stupean@gmail.com
// Screener: https://t.me/LazyScalp
// © stupean

//@version=5

// @description v1.2.0
library("HLevel", true)

//#region CONSTANTS ============================================
string SIDE_HIGH = "SIDE_HIGH"
string SIDE_LOW = "SIDE_LOW"
int LOCAL_PERIOD = 0
int MIDDLE_PERIOD = 1
int GLOBAL_PERIOD = 2
int BREAK_PERIOD = 3
//#endregion

//#region CLASS Pivots ============================================
export type pivot
    int period
    int legBars
    float hPrice
    float lPrice

export type pivotsList
    int secondsInCurrentPeriod
    array<pivot> pivots

export method init(pivotsList this, int secondsInCurrentPeriod) =>
    this.pivots := array.new<pivot>()
    this.secondsInCurrentPeriod := secondsInCurrentPeriod

export method add(pivotsList this, int period, int legSeconds) =>
    int legBars = math.ceil(legSeconds * 1.5 / this.secondsInCurrentPeriod)
    pivot p = pivot.new(
      period = period,
      legBars = legBars,
      hPrice = ta.pivothigh(high, legBars, legBars),
      lPrice = ta.pivotlow(low, legBars, legBars))
    this.pivots.push(p)
    p

export method size(pivotsList this) =>
    this.pivots.size()

export method get(pivotsList this, int index) =>
    this.pivots.get(index)
//#endregion

//#region CLASS Levels ============================================
export type level
    string side
    int barIndex
    int crossBarIndex = -1
    float price
    line lineId
    int period
    bool hasNearLevel
    bool isHide
    label priceLableId

method time(level this) =>
    int bars = bar_index - this.barIndex
    timeframe.in_seconds(timeframe.period) * bars

export type levelsClass
    int maxBars
    int minNearLevels
    array<int> lifetimes
    array<level> levels

method resetNearLevels(levelsClass this) =>
    if this.levels.size() > 0
        for i = 0 to this.levels.size() - 1
            level lvl = this.levels.get(i)
            lvl.hasNearLevel := false

export method init(levelsClass this, int minNearLevels, int maxBars = 4000) =>
    this.levels := array.new<level>()
    this.lifetimes := array.new<int>(10, -1)
    this.maxBars := maxBars
    this.minNearLevels := minNearLevels

export method addLifetime(levelsClass this, int period, int lifetimeBars) =>
    this.lifetimes.set(period, lifetimeBars)

export method size(levelsClass this) =>
    this.levels.size()

export method getAll(levelsClass this) =>
    this.levels

export method get(levelsClass this, int index) =>
    this.levels.get(index)

export method delete(levelsClass this, int index) =>
    level lvl = this.levels.get(index)
    if not na(lvl.lineId)
        lvl.lineId.delete()
    if not na(lvl.priceLableId)
        lvl.priceLableId.delete()
    this.levels.remove(index)

export method isLifetimeExpired(levelsClass this, level lvl) =>
    int lifetime = this.lifetimes.get(lvl.period)
    if lifetime == 0
        false
    else if lvl.barIndex < bar_index - lifetime
        true
    else
        false

method markStrongLevels(levelsClass this, level lvl, int nextLevelIndex, distanceBetweenNearLevels) =>
    array<level> strongLevels = array.new<level>()
    strongLevels.push(lvl)
    if nextLevelIndex < this.levels.size() and lvl.crossBarIndex == -1 and not lvl.isHide 
        for int i = nextLevelIndex to this.levels.size() - 1
            level secondLvl = this.levels.get(i)
            if secondLvl.crossBarIndex == -1 and math.abs(lvl.price - secondLvl.price) <= distanceBetweenNearLevels and not secondLvl.isHide
                strongLevels.push(secondLvl)
    if strongLevels.size() > 0 and strongLevels.size() >= this.minNearLevels 
        for int i = 0 to strongLevels.size() - 1
            level _level = strongLevels.get(i)
            _level.hasNearLevel := true
 
export method update(levelsClass this, pivotsList pivots, float priceRange, float distanceBetweenNearLevels) =>
    pivot p = pivots.get(0)
    if not na(p.hPrice) 
        level newLevel = level.new(
          side = SIDE_HIGH,
          barIndex = bar_index - p.legBars,
          price = p.hPrice,
          period = p.period)
        this.levels.unshift(newLevel)

    if not na(p.lPrice)
        level newLevel = level.new(
          side = SIDE_LOW,
          barIndex = bar_index - p.legBars,
          price = p.lPrice,
          period = p.period)
        this.levels.unshift(newLevel)

    this.resetNearLevels()

    int counter = 0
    while counter < this.levels.size()
        level lvl = this.levels.get(counter)
        // delete old level
        if (lvl.barIndex < bar_index - this.maxBars)
            this.delete(counter)
            continue

        // mark cross level
        bool isCross = lvl.side == SIDE_HIGH ? lvl.price < high : lvl.price > low
        if isCross and lvl.crossBarIndex == -1
            lvl.crossBarIndex := bar_index

        // delete crossed level
        if lvl.crossBarIndex != -1 and lvl.crossBarIndex < bar_index - this.lifetimes.get(BREAK_PERIOD)
            this.delete(counter)
            continue

        // define senior levels
        for pivotIndex = pivots.size() - 1 to 1
            pivot piv = pivots.get(pivotIndex) 
            if (lvl.side == SIDE_HIGH and lvl.price == piv.hPrice) or (lvl.side == SIDE_LOW and lvl.price == piv.lPrice)
                lvl.period := piv.period
                lvl.isHide := false
                break
      
        // hide far levels
        float maxPrice = close + priceRange
        float minPrice = close - priceRange
        if (lvl.side == SIDE_HIGH and lvl.price > maxPrice) or (lvl.side == SIDE_LOW and lvl.price < minPrice )
            lvl.isHide := true
        else if lvl.isHide
            lvl.isHide := false    

        // hide expired levels
        if this.isLifetimeExpired(lvl)
            lvl.isHide := true

        // mark nearly levels
        int nextLevelIndex = counter + 1 
        this.markStrongLevels(lvl, nextLevelIndex, distanceBetweenNearLevels)
        
        counter += 1

export method getNearStrongLevels(levelsClass this) =>
    level highLevel = na
    level lowLevel = na
    if this.size() > 0
        for i = 0 to this.size() - 1
            level lvl = this.get(i)
            if not lvl.hasNearLevel
                continue
            if lvl.side == SIDE_HIGH 
                if na(highLevel)
                    highLevel := lvl
                else if lvl.price < highLevel.price
                    highLevel := lvl
            else if lvl.side == SIDE_LOW 
                if na(lowLevel)
                    lowLevel := lvl
                else if lvl.price > lowLevel.price
                    lowLevel := lvl

    [highLevel, lowLevel] 
//#endregion

//#region CLASS Drawer ============================================
export type lineStyle
    int width = 1
    color lineColor
    string style = line.style_solid

export type levelDrawerClass
    array<lineStyle> styles
    color roundPriceColor
    color defaultPriceColor
    string priceShowOptions
    float transparent
    bool showLevelTime

export method init(levelDrawerClass this, string priceShowOptions, float transparent = 70, color roundPriceColor = color.green, color defaultPriceColor = color.white) =>
    this.styles := array.new<lineStyle>()
    this.roundPriceColor := roundPriceColor
    this.defaultPriceColor := defaultPriceColor
    this.priceShowOptions := priceShowOptions
    this.transparent := transparent

export method addStyle(levelDrawerClass this, lineStyle style) =>
    this.styles.push(style)

export method draw(levelDrawerClass this, levelsClass levelList) =>
    if levelList.size() > 0
        lineStyle breakStyle = this.styles.last()
        for i = 0 to levelList.size() - 1
            level lvl = levelList.get(i)
            lineStyle lStyle = this.styles.get(lvl.period)
            if lvl.isHide 
                if not na(lvl.lineId)
                    lvl.lineId.delete()
                if not na(lvl.priceLableId)
                    lvl.priceLableId.delete()
                continue

            float transparent = lvl.hasNearLevel ? 0 : this.transparent
            color lineColor = color.new(lStyle.lineColor, transparent)
            if na(lvl.lineId)
                lvl.lineId := line.new(
                  x1 = lvl.barIndex,
                  y1 = lvl.price,
                  x2 = lvl.barIndex + 1,
                  y2 = lvl.price,
                  extend = extend.right,
                  color = lineColor,
                  style = lStyle.style,
                  width = lStyle.width)  
                0
            else if lvl.crossBarIndex != -1
                lvl.lineId.set_color(breakStyle.lineColor) 
                lvl.lineId.set_style(breakStyle.style) 
                lvl.lineId.set_width(breakStyle.width) 
                lvl.lineId.set_x2(lvl.crossBarIndex + 10) 
                lvl.lineId.set_extend(extend.none) 
                0
            else
                lvl.lineId.set_color(lineColor) 
                lvl.lineId.set_style(lStyle.style) 
                lvl.lineId.set_width(lStyle.width) 

            if this.priceShowOptions != "none"
                color textColor = if math.round_to_mintick(lvl.price / 100) * 100 == lvl.price 
                    color.new(this.roundPriceColor, transparent)
                else
                    color.new(this.defaultPriceColor, transparent)

                string labelText = str.tostring(lvl.price)
                if this.showLevelTime
                    labelText += str.format("\n{0,number,#}h", lvl.time() / 3600)

                if na(lvl.priceLableId)
                    lvl.priceLableId := label.new(
                      x = lvl.barIndex,
                      y = 0,
                      text =  labelText,
                      size = this.priceShowOptions,
                      style = label.style_none,
                      textcolor = textColor,
                      yloc = lvl.side == SIDE_HIGH ? yloc.abovebar : yloc.belowbar)
                    0
                else if lvl.crossBarIndex != -1
                    lvl.priceLableId.set_textcolor(breakStyle.lineColor)
                    0
                else
                    lvl.priceLableId.set_textcolor(textColor)
                    lvl.priceLableId.set_text(labelText)
                    0
//#endregion