Golden / Death Cross

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Piotr Kowalski "piecioshka"
// Docs (EN): https://github.com/piecioshka/tradingview-pine-scripts/blob/main/indicators/overlays/golden-death-cross/golden-death-cross.md
// Docs (PL): https://github.com/piecioshka/tradingview-pine-scripts/blob/main/indicators/overlays/golden-death-cross/golden-death-cross.pl.md

//@version=6
indicator('Golden / Death Cross', overlay=true, max_labels_count=500)

// Golden Cross — the fast average crosses the slow one from below (bullish signal).
// Death Cross — the fast average crosses the slow one from above (bearish signal).
// Classic setting: SMA 50 vs SMA 200.

fastColor = color.rgb(56, 104, 174)
slowColor = color.rgb(215, 107, 52)

fastLen = input.int(50, 'Fast MA (length)', minval=1)
slowLen = input.int(200, 'Slow MA (length)', minval=1)
src = input.source(close, 'Source')

gA = 'Appearance'
shapeName = input.string('Triangle', 'Marker shape', options=['Triangle', 'Arrow', 'Label arrow', 'Circle', 'Diamond'], group=gA, tooltip='Triangle - solid triangle.\nArrow - small thin arrow.\nLabel arrow - arrow-shaped label bubble.\nCircle / Diamond - neutral dot markers.')
sizeName  = input.string('Small', 'Marker size', options=['Tiny', 'Small', 'Normal', 'Large'], group=gA)

// Markers as labels - the shape is picked from an input, which plotshape() cannot do (its style must be a constant).
upStyle    = shapeName == 'Arrow' ? label.style_arrowup : shapeName == 'Label arrow' ? label.style_label_up : shapeName == 'Circle' ? label.style_circle : shapeName == 'Diamond' ? label.style_diamond : label.style_triangleup
downStyle  = shapeName == 'Arrow' ? label.style_arrowdown : shapeName == 'Label arrow' ? label.style_label_down : shapeName == 'Circle' ? label.style_circle : shapeName == 'Diamond' ? label.style_diamond : label.style_triangledown
markerSize = sizeName == 'Tiny' ? size.tiny : sizeName == 'Normal' ? size.normal : sizeName == 'Large' ? size.large : size.small

fastMA = ta.sma(src, fastLen)
slowMA = ta.sma(src, slowLen)

plot(fastMA, 'Fast SMA', color=fastColor, linewidth=2)
plot(slowMA, 'Slow SMA', color=slowColor, linewidth=2)

goldenCross = ta.crossover(fastMA, slowMA)
deathCross = ta.crossunder(fastMA, slowMA)

if (goldenCross)
    line.new(bar_index, high, bar_index, low, color=color.new(color.green, 50), style=line.style_dashed, extend=extend.both)
    label.new(bar_index, slowMA, 'GOLDEN CROSS', color=color.new(color.green, 30), textcolor=color.white, style=label.style_label_up, size=size.normal)
    label.new(bar_index, na, '', yloc=yloc.belowbar, style=upStyle, color=color.green, size=markerSize)

if (deathCross)
    line.new(bar_index, high, bar_index, low, color=color.new(color.red, 50), style=line.style_dashed, extend=extend.both)
    label.new(bar_index, slowMA, 'DEATH CROSS', color=color.new(color.red, 30), textcolor=color.white, style=label.style_label_down, size=size.normal)
    label.new(bar_index, na, '', yloc=yloc.abovebar, style=downStyle, color=color.red, size=markerSize)

// --- Alerts ---
alertcondition(goldenCross, 'Golden cross', 'Golden cross - the fast SMA crossed the slow one up (bullish signal)')
alertcondition(deathCross,  'Death cross',  'Death cross - the fast SMA crossed the slow one down (bearish signal)')