Fibonacci Weighted Moving Average

//@version=6
// Copyright (c) 2018-present, Alex Orekhov (everget)
// Fibonacci Weighted Moving Average script may be freely distributed under the MIT license.
const string MA_SHORT_TITLE = 'FWMA'
indicator('Fibonacci Weighted Moving Average', shorttitle = MA_SHORT_TITLE, overlay = true, behind_chart = false)

length = input.int(14, minval = 1, title = 'Length')
src = input.source(close, title = 'Source')

var highlightDirectionTooltip = 'Colors the ' + MA_SHORT_TITLE + ' according to its direction:\n• Green = rising\n• Pink = falling'
highlightDirection = input.bool(
     true
     , title = 'Highlight Direction'
     , tooltip = highlightDirectionTooltip
     )

var applyBarColorsTooltip = 'Colors price bars according to the ' + MA_SHORT_TITLE + ' direction:\n• Bullish color = rising ' + MA_SHORT_TITLE + '\n• Bearish color = falling ' + MA_SHORT_TITLE
applyBarColors = input.bool(
     true
     , title = 'Apply Bar Colors'
     , tooltip = applyBarColorsTooltip
     )

var applyBgColorsTooltip = 'Colors the chart background according to the ' + MA_SHORT_TITLE + ' direction:\n• Bullish color = rising ' + MA_SHORT_TITLE + '\n• Bearish color = falling ' + MA_SHORT_TITLE
applyBgColors = input.bool(
     false
     , title = 'Apply Background Colors'
     , tooltip = applyBgColorsTooltip
     )

//---

// Fibonacci weights, heaviest on the newest bar.
// Built iteratively - exact integers, no Binet round-off - and only once, since the kernel depends solely on `length`.
var array<float> weights = array.new_float(0)
var float weightSum = 0.0
if array.size(weights) == 0
    prev = 0.0
    curr = 1.0
    for i = 1 to length
        array.push(weights, curr)
        weightSum += curr
        nextFib = prev + curr
        prev := curr
        curr := nextFib
    // pushed F(1)..F(length); reverse so index 0 (the newest bar) carries F(length)
    array.reverse(weights)

sum = 0.0
for i = 0 to length - 1
    sum += nz(src[i], src) * array.get(weights, i)

ma = sum / weightSum

//---

const color bullishColor = #09b71e
const color bearishColor = #e91e63

const color bullishBarColor = color.new(bullishColor, 50)
const color bearishBarColor = color.new(bearishColor, 50)

const color bullishWickColor = bullishColor
const color bearishWickColor = bearishColor

const color bullishBgColor = color.new(bullishColor, 88)
const color bearishBgColor = color.new(bearishColor, 88)

isBullishSlope = ma > ma[1]

maColor = highlightDirection
     ? (isBullishSlope ? bullishColor : bearishColor)
     : #512da8

plot(ma, title = MA_SHORT_TITLE, linewidth = 2, color = maColor)

maBarColor = applyBarColors ? (isBullishSlope ? bullishBarColor : bearishBarColor) : na
maWickColor = applyBarColors ? (isBullishSlope ? bullishWickColor : bearishWickColor) : na
maBgColor = applyBgColors ? (isBullishSlope ? bullishBgColor : bearishBgColor) : na

barcolor(title = 'Bar Color', color = maBarColor)
plotcandle(open, high, low, close, title = 'Bar Color', color = na, wickcolor = maWickColor, bordercolor = na, display = display.pane)
bgcolor(title = 'Background Color', color = maBgColor)

//---

bullishColorChangeAlert = maColor[1] != bullishColor and maColor == bullishColor
bearishColorChangeAlert = maColor[1] != bearishColor and maColor == bearishColor
anyColorChangeAlert = maColor != maColor[1]

alertcondition(bullishColorChangeAlert, title = 'Bullish Color Change', message = MA_SHORT_TITLE + ' - Bullish Color Change\nSymbol: {{exchange}}:{{ticker}}\nPrice: {{close}}')
alertcondition(bearishColorChangeAlert, title = 'Bearish Color Change', message = MA_SHORT_TITLE + ' - Bearish Color Change\nSymbol: {{exchange}}:{{ticker}}\nPrice: {{close}}')
alertcondition(anyColorChangeAlert, title = 'Any Color Change', message = MA_SHORT_TITLE + ' - Any Color Change\nSymbol: {{exchange}}:{{ticker}}\nPrice: {{close}}')