Equity Trading Strategy

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Amjad_S

//@version=6
//+------------------------------------------------------------------+
//                                                         INDICATOR |
//<<+----------------------------------------------------------------+{
indicator("EQUITY TRADING STRATEGY", 
     overlay = true, 
     behind_chart = false)

//>>+----------------------------------------------------------------+}
//                                                            INPUTS |
//<<+----------------------------------------------------------------+{
int volume_window = input(1, title = 'Volume Window')

// sl and tp 
atr = ta.atr(14)
float atr_mult = input(3.0, title = 'ATR SL MULTIPLIER')
float rr = input(1.0, title = 'RISK REWARD')

//>>+----------------------------------------------------------------+}
//                                                        INDICATORS |
//<<+----------------------------------------------------------------+{
// vwap --------------------------------------------------------------
vwap_anchor = timeframe.change('D')
vwap = ta.vwap(ohlc4, anchor = vwap_anchor) 

//>>+----------------------------------------------------------------+}
//                                                        CONFLUENCE |
//<<+----------------------------------------------------------------+{
// outlier volume 
avg_volume = ta.sma(volume, volume_window)
outlier_volume = volume_window > 1 ? volume > avg_volume : true

// first bars 
var bars = 0 
var time_elapsed = false

if vwap_anchor
    bars := 0
    time_elapsed := false
else 
    bars += 1 

if bars > 12 // 5 * 12 = 1hour 
    time_elapsed := true 

bgcolor(time_elapsed and not time_elapsed[1] ? color.new(color.white, 90) : na)

//>>+----------------------------------------------------------------+}
//                                                           SIGNALS |
//<<+----------------------------------------------------------------+{
long_signal = (close < vwap) and (high >= vwap)
long_signal_conf = (close > vwap) and long_signal[1]
long_valid = long_signal_conf[1] and (outlier_volume[1] and time_elapsed)

short_signal = (close > vwap) and (low <= vwap)
short_signal_conf = (close < vwap) and short_signal[1]
short_valid = short_signal_conf[1] and (outlier_volume[1] and time_elapsed)

//>>+----------------------------------------------------------------+}
//                                                           SL & TP |
//<<+----------------------------------------------------------------+{
rd(val) =>
    math.round(val, 5)

sl_tp(order) =>
    side = order == 'long' ? 1 : order == 'short' ? -1 : na 
    sl_dist = atr * atr_mult 
    sl = rd(open - sl_dist * side)
    tp = rd(open + sl_dist * side * rr)
    [sl, tp]

//>>+----------------------------------------------------------------+}
//                                                  VALIDATE SIGNALS |
//<<+----------------------------------------------------------------+{
long_trigger = long_valid and not long_valid[1]
short_trigger = short_valid and not short_valid[1] 

var FirstTrade = bool(na) 

if vwap_anchor
    FirstTrade := false 
else
    if long_trigger or short_trigger
        FirstTrade := true

FirstTradeValid = FirstTrade and not FirstTrade[1]

//>>+----------------------------------------------------------------+}
//                                                      SIGNAL PLOTS |
//<<+----------------------------------------------------------------+{
if long_trigger
    [sl, tp] = sl_tp('long')

    label.new(x = bar_index, y = low, 
        text = 'long' + '\n' + 'sl: @' + str.tostring(sl) + '\n' + 'tp: @' + str.tostring(tp), 
        color = FirstTradeValid ? color.green : color.gray,
        style = label.style_label_up)

    if FirstTradeValid
        alert(message = "LONG " + syminfo.ticker + " " + timeframe.period + " ent: @" + str.tostring(close, format.mintick) + 'sl: @' + str.tostring(sl) + 'tp: @' + str.tostring(tp),
             freq = alert.freq_once_per_bar)

if short_trigger
    [sl, tp] = sl_tp('short')

    label.new(x = bar_index, y = high, 
        text = 'short' + '\n' + 'sl: @' + str.tostring(sl) + '\n' + 'tp: @' + str.tostring(tp), 
        color = FirstTradeValid ? color.red : color.gray,
        style = label.style_label_down)

    if FirstTradeValid
        alert(message = "SHORT " + syminfo.ticker + " " + timeframe.period + " ent: @" + str.tostring(close, format.mintick) + 'sl: @' + str.tostring(sl) + 'tp: @' + str.tostring(tp),
             freq = alert.freq_once_per_bar)

//>>+----------------------------------------------------------------+}
//                                                   INDICATOR PLOTS |
//<<+----------------------------------------------------------------+{
plot(vwap, title = 'VWAP', color = color.purple)