Daddy's Turtle Strategy

// Breakout-based trend indicator that enters when price breaks user-defined highs or lows,
// adds positions as the trend continues, and uses ATR for stops.
// © Timo Anttila, Tuspe Design Oy

//@version=6
indicator("Daddy's Turtle Strategy", shorttitle="Turtle", overlay=true, max_labels_count=200)

group1 = "Numbers of clearing bars"
entry_bars = input.int(20, "Entry", group=group1)
exit_bars = input.int(10, "Exit", group=group1)

group2 = "Average True Range"
atr_length = input.int(20, "Length", group=group2)
atr_buffer_m = input.float(0.1, "Buffer multiplier", group=group2)
atr_max_m = input.float(3.5, "Max candle size multiplier", group=group2)

group4 = "Entry Settings"
min_body_perc = input.float(20, "Min entry candle body %", minval=20, maxval=95, group=group4)
only_longs = input.bool(false, "Only longs", group=group4)


// ----------
//  GLOBAL VARIABLES
// ----------

bool is_bear = close < open
bool is_bull = close > open
float atr = ta.atr(atr_length)
int entry = na
int exit = na
var bool entry_taken = false
var float candle_exit = na
var float pullback = na
var int trend = na


// ----------
//  EXIT / ATR FIX
// ----------

float exit_highest = ta.highest(high, exit_bars)[1]
float exit_lowest = ta.lowest(low, exit_bars)[1]

if entry_taken
    if trend == 1 and (close < exit_lowest or close < candle_exit)
        exit := 1

    else if trend == 2 and (close > exit_highest or close > candle_exit)
        exit := 2

    if not na(exit)
        entry_taken := false


// ----------
//  ENTRY
// ----------

float entry_highest = ta.highest(high, entry_bars)[1]
float entry_lowest = ta.lowest(low, entry_bars)[1]

if not entry_taken
    float body_size = math.abs(close - open)
    float candle_size = math.abs(high - low)

    if body_size / candle_size >= min_body_perc / 100 and candle_size < atr * atr_max_m
        float atr_buffer = atr * atr_buffer_m

        if is_bull and close > entry_highest + atr_buffer
            entry := 1
            trend := 1

        else if not only_longs and is_bear and close < entry_lowest - atr_buffer
            entry := 2
            trend := 2

        if not na(entry)
            float atr_exit = atr * 2
            candle_exit := trend == 1 ? close - atr_exit : close + atr_exit
            entry_taken := true

            if not na(exit)
                exit := na


// ----------
//  VISUAL
// ----------

entry_color = color.new(color.white, 30)
plot_size = size.tiny
plot_bull = location.belowbar
plot_bear = location.abovebar

plotshape(entry == 1, title="Turtle Long", style=shape.triangleup, location=plot_bull, color=entry_color, size=plot_size)
plotshape(entry == 2, title="Turtle Short", style=shape.triangledown, location=plot_bear, color=entry_color, size=plot_size)

plot_style = shape.xcross
plot_color = color.new(color.gray, 20)

plotshape(exit == 1, title="Long Exit", style=plot_style, location=plot_bull, color=plot_color, size=plot_size)
plotshape(exit == 2, title="Short Exit", style=plot_style, location=plot_bear, color=plot_color, size=plot_size)


// ----------
//  ALERTS
// ----------

bool alert_check = not na(entry)
alertcondition(alert_check, title="New Signal", message="New signal detected. Confirm the direction of the next candle before entering. Happy trading!")
alertcondition(not na(exit), title="Cash Out", message="It might be a good time to close your position now.")