Corrected Moving Average

//@version=6
// Copyright (c) 2020-present, Alex Orekhov (everget)
// Corrected Moving Average script may be freely distributed under the terms of the GPL-3.0 license.
const string MA_SHORT_TITLE = 'CMA'
indicator('Corrected Moving Average', shorttitle = MA_SHORT_TITLE, overlay = true, behind_chart = false)

length = input.int(35, minval = 1, title = 'Length')
src = input.source(close, title = 'Source')
highlightDirection = input.bool(false, title = 'Highlight CMA')
applyRibbonFilling = input.bool(true, title = 'Apply Ribbon Filling')

//---

sma = ta.sma(src, length)
cma = sma

cmaPrev = nz(cma[1], sma)
v1 = ta.variance(src, length)
dev = cmaPrev - sma
v2 = dev * dev
v3 = v1 == 0 or v2 == 0 ? 1 : v2 / (v1 + v2)
// Closed form of the original fixed-point iteration k <- v3 * k * (2 - k) seeded at k = 1.
// Its nonzero root is k = 2 - 1/v3, which goes negative for v3 <= 0.5 (there the iteration collapses toward 0), so clamp at 0.
// Replaces a 1001-pass loop with one division.
k = math.max(0.0, 2 - 1 / v3)
cma := cmaPrev + k * (sma - cmaPrev)

//---

cmaColor = highlightDirection ? cma > cma[1] ? color.green : color.red : color.orange
cmaPlot = plot(cma, title = MA_SHORT_TITLE, linewidth = 2, color = cmaColor)
smaPlot = plot(sma, title = 'SMA', linewidth = 2, color = color.blue)

var bullishFillColor = color.new(#0ebb23, 75)
var bearishFillColor = color.new(#cc0000, 75)

fillColor = applyRibbonFilling ? (sma > cma ? bullishFillColor : bearishFillColor) : #ffffff00
fill(smaPlot, cmaPlot, color = fillColor)

longSignal = ta.crossover(sma, cma)
shortSignal = ta.crossunder(sma, cma)

alertcondition(longSignal, title = 'Long Signal', message = 'Enter Long\nSymbol: {{exchange}}:{{ticker}}\nPrice: {{close}}')
alertcondition(shortSignal, title = 'Short Signal', message = 'Enter Short\nSymbol: {{exchange}}:{{ticker}}\nPrice: {{close}}')