ATR Rope

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © SamRecio

//@version=6
indicator("ATR Rope", overlay = true)

///_____________________________________________________________________________________________________________________
///Inputs
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

var params = "Parameters"
src = nz(input.source(close, title = "Source", group = params))
len = input.int(14, title = "ATR Len", group = params)
multi = input.float(1.5, title = "Multi", step = 0.25, minval = 0, group = params)

var disp = "Display"
rng_tog = input.bool(true, title = "Consolidation Ranges", group = disp)
atr_tog = input.bool(false, title = "ATR Channel", group = disp)

var cols = "Colors"
up_col = input.color(#3daa45, title = "Up Color", group = cols)
down_col = input.color(#ff033e, title = "Down Color", group = cols)
flat_col = input.color(#004d92, title = "Flat Color", inline = "3", group = cols)
rng_col = input.color(#004d9233, title = "", inline = "3", group = cols)

///_____________________________________________________________________________________________________________________
///Function
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

//Smooths a Source similar to Rope Stabilization in a Drawing Application. OR a "Range Filter" as some might say ;)
rope_smoother(float _src, float _threshold) =>

    var float _rope = _src

    _move = _src - _rope //Movement from Rope

    _rope += math.max(math.abs(_move) - nz(_threshold), 0) * math.sign(_move) //Directional Movement beyond the Threshold
    
    [_rope,_rope+_threshold,_rope-_threshold] //[Rope, Upper, Lower]

///_____________________________________________________________________________________________________________________
///Rope Calcs
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

//Calculating Rope
atr = ta.atr(len)*multi

[rope,upper,lower] = rope_smoother(src,atr)

//Directional Detection
var dir = 0

dir := rope > rope[1] ? 1 : rope < rope[1] ? -1 : dir

if ta.cross(src,rope)
    dir := 0

//Directional Color Assignment    
col = dir > 0 ? up_col : dir < 0 ? down_col : flat_col

///_____________________________________________________________________________________________________________________
///Consolidation Ranges
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

//High and Low Output Lines
var float c_hi = na
var float c_lo = na

//Counters for Accumulating Averages
var float h_sum = 0
var float l_sum = 0
var int c_count = 0

//Flip-Flop
var ff = true

//Flip Flop, Pip Slip Top,
//Bear Drop, Bull Pop, Lunch Time Chop,
//Tight Stop, Desktop Prop.
if dir == 0

    if dir[1] != 0
        h_sum := 0
        l_sum := 0
        c_count := 0
        ff := not ff

    h_sum += upper
    l_sum += lower
    c_count += 1
    c_hi := h_sum/c_count
    c_lo := l_sum/c_count

///_____________________________________________________________________________________________________________________
///Display
///‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾‾

//Rope
plot(rope, linewidth = 3, color = col, title = "Rope", force_overlay = true)

//Channel
plot(upper, display = atr_tog?display.all:display.none, color = col, title = "Upper", force_overlay = true)
plot(lower, display = atr_tog?display.all:display.none, color = col,  title = "Lower", force_overlay = true)

//Consolidation Ranges

h1 = plot(ff?na:c_hi, style = plot.style_linebr, color = color.new(rng_col,0), display = rng_tog?display.all:display.none, title = "Range High 1")
l1 = plot(ff?na:c_lo, style = plot.style_linebr, color = color.new(rng_col,0), display = rng_tog?display.all:display.none, title = "Range Low 1")

h2 = plot(ff?c_hi:na, style = plot.style_linebr, color = color.new(rng_col,0), display = rng_tog?display.all:display.none, title = "Range High 2")
l2 = plot(ff?c_lo:na, style = plot.style_linebr, color = color.new(rng_col,0), display = rng_tog?display.all:display.none, title = "Range Low 2")

fill(h1,l1,rng_col, display = rng_tog?display.all:display.none, title = "Range 1 Fill")
fill(h2,l2,rng_col, display = rng_tog?display.all:display.none, title = "Range 2 Fill")